*comment Language switches
*temp father_oath "undetermined"

*temp mother_contact "undetermined"
*temp mother_ancestors "undetermined"

*temp clever_entrance "undetermined"
*temp invocation "undetermined"
*temp your_mother_and ""

*text_image chap_1.png center Chapter One: The World That Remains

"It was a clear cold morning, my child, and Hareetha knew she was doomed. Behemoth Mountain lay in ruins, but I could hear her laughing. For was her god not the god of ruin?"

Your mother stirs the ashes. Quick, angry motions. Everyone else who tells the story of the war rushes toward its glorious conclusion. Not her. She stabs at the story, poking at bits and pieces, like a bored celebrant at one of Empress Zoriza's desert feasts. Suddenly she returns to the beginning.

"I was no older than you when I left home to seek glory battling the dark priestess. Me and Pon, the warrior kings Hyras and Vankred, Col the satyr with his clever strategies, Heroch the Navigator who guarded us at sea, and little Zoriza. Oh, and the one I told you never to mention—the Golden Archer. I was young, but already…"

Your mother, Para, lapses into reflective silence. But you know the story.
*choice
	#"You were already the swiftest hunter among the forest tribes."
		*set grace +1
		*set mother_origin "Forest"
		*set mother_origin_specific "Thorn tribe"
		*set mother_born "Born to the Thorn tribe in the Northern Forest, Para proved herself early on as one of the tribe's swiftest and most deadly hunters"
		*set your_mother_and "your mother and "
		*set mother_hair "red"
		*set mother_sword "short bronze"
		*set mother_contact "hunters and trappers from the Thorn tribe"
		*set mother_ancestors "the hunters of the Thorn tribe"
		Your mother smiles into the ashes. "The Thorn tribe had never seen anyone like me," she says. "In my youth, I could race through the forests here quicker than any wolf. Once, I did. I ran all night and warned my father that a pack was coming. That's how I met your father." She points her blackened stick at you. "You, too, have that speed. If you would only try."
	#"You were already a renowned warrior of the Sea Kingdom."
		*set might +1
		*set mother_origin "Sea"
		*set mother_origin_specific "Corini"
		*set mother_born "Born in the great trading city of Corini, part of the Sea Kingdom, Para began life as a humble dock guard but quickly proved herself and rose through the ranks"
		*set your_mother_and "your mother and "
		*set mother_hair "brown"
		*set mother_sword "straight-bladed bronze"
		*set mother_contact "merchants from the Sea Kingdom cities of Corini and Tralcho"
		*set mother_ancestors "her clever seafaring ancestors"
		Your mother smiles into the ashes. "Corini is famous for its sailors, but in those days every ship needed a guard to stop pirates and dockside thieves," she says. "My first night, three Peithian mercenaries crept aboard. They were fresh from plundering the Southern Coast and had swords of bronze. I only had an oak staff. Afterward, I kept one sword and sold the other two to your father. That's how I met him." She points her blackened stick at you. "You, too, have that strength, that ferocity. If only you would use it."
	#"You were already a tireless and disciplined protector of the desert clans, defending their rights against the arrogance of the city lords."
		*set resolve +1
		*set mother_origin "Desert"
		*set mother_origin_specific "Goat clan"
		*set mother_born "Born the youngest daughter of a Goat clan chieftain, Para proved a stubborn advocate for those distrusted people but soon left them to become a merchant"
		*set mother_hair "curly black"
		*set mother_sword "curved bronze"
		*set mother_contact "dwarrow and human traders from the Mountains of Jann"
		*set mother_ancestors "her devious ancestors among the water clans of the Western Desert"
		Your mother smiles into the ashes. "The Goat clan was the poorest water clan in the Western Desert that still recognized the heavenly gods," she says. "But I knew my worth and hated the city lords and temple priests, who saw us as beggars and wild dogs. I learned their ways, too. To protect my people, I disputed with a vain and cruel merchant all night to secure my clan access to a well. The next morning a new, better man had replaced that cruel merchant. Your father. That is how we met." She points her blackened stick at you. "You, too, have that resolute passion, that willingness to endure. If only you would use it."

*set c_para true

She brushes the ${mother_hair} hair from her face, tugging absently at a lock now streaked with gray, then her eyes get a faraway look as she remembers Hareetha and the ruins of Behemoth Mountain.

"It was not easy to enter the mountain, even with it shattered and burning. The two kings and I were exhausted from battle. But your father already knew a way inside."

Your father, Pon, was never prone to boasting, but he loved that story. All those great heroes, standing outside the sealed gate of a blasted mountain, bickering like spice merchants because no one knew how to get inside. And then…
*choice
	#He pulled a bent lockpick out of his scabbard and got them in through a neglected cistern.
		*set burglar +1
		*set artisan +1
		*set father_gift "engineering talent"
		*set clever_entrance "neglected cistern your father unlocked"
		"Then Pon held something up to the light of Zoriza's lamp. We kept arguing, of course, even as he slid the piece of iron into an old lock and forced the mechanism. Your father had a gift for machines. And for getting into places where he wasn't allowed. You have inherited his talents, I've noticed. Others have noticed, too. Be careful, my child, with what your father has taught you."
	#Armed with a bow, he crept through the desert grass and ambushed the lions guarding a secret gate.
		*set naturalist +1
		*set archer +1
		*set father_gift "prowess as a hunter"
		*set clever_entrance "southern gate your father forced open"
		"We kept arguing until we realized Pon had disappeared. Then we heard the horned lions of Hareetha roar once…but only once. When we reached the southern gate, they lay dead. One had seen nothing until the arrow struck, so skilled was your father at hunting wild beasts. The other had fought with teeth and claws and horns, but Pon was a deadly hunter. Not as ferocious as the two kings, of course, but who could stand against them in single combat? Still, he killed the lions, the Golden Archer killed the guards at the gate, and we were inside."

		Para studies you and says, "I know he taught you how to survive in these woods and to hunt both man and beast. But he did not teach you everything. Do not think yourself a great hero. At least, not yet."
	#Long ago, he had bartered a map of the tower from a priest of the god of lies. (And kept his soul in the process!)
		*set diplomat +1
		*set scholar +1
		*set father_gift "talents for negotiation and scholarship"
		*set clever_entrance "unguarded window your father's map revealed"

		"We kept arguing even as Pon drew out a leather scroll and started sketching diagrams in the sand. I learned only later that he had haggled in Patabesh, the City of Thieves, with a priest of the god of knots. Your father was always a gifted negotiator and a brilliant scholar, and he proved himself then by getting us inside the tower through an unguarded window. We always respected his resourcefulness, which you have inherited, my child."

*set trained true

You touch the beads you wear around your throat. One symbolizes your father's ${father_gift}.
*choice
	#A chip of amethyst representing Amiria, worshipped in Pon's forest home as the goddess of glory and charisma.
		*set father_origin "Forest"
		*set bearing +1
		*set father_bead "a chip of amethyst sacred to Amiria"
		*if father_gift = "engineering talent"
			*set father_origin_specific "Rowan tribe"
			*set father_born "The son of a river trader from the Northern Forest's Rowan tribe, Pon demonstrated a merchant's guard, then a merchant himself"
			*set clothing_design "a braided design of pine and rowan trees"
			*set father_oath "the golden words of ${amiria}"
			*set invocation "the goddess of eloquence"
			The Sea Kingdom calls Amiria the goddess of love, but to the Northern river folk in the Rowan tribe, from which your father hailed, she represents regal bearing, dignity, oratorical brilliance, and grandeur. And, yes, also the ability to sneak into places where you do not belong, but only when necessary. The amethyst fragment is cold and sharp against your fingers. You remember your father's eloquence and kingly bearing, and hope that you have inherited some fraction of his dignity.
		*if father_gift = "prowess as a hunter"
			*set father_origin_specific "Oak tribe"
			*set father_born "The son of an Oak tribe warrior, Pon grew up in the Northern Forest, then traveled south to make his fortune"
			*set clothing_design "a braided design of interlocked oak and pine trees"
			*set father_oath "the raised hand of blessed ${amiria}"
			*set invocation "the goddess of honorable contests"
			The Sea Kingdom calls Amiria the goddess of love, but to the Northern warriors in the Oak tribe, from which your father hailed, she is the goddess of both power and beauty. To hunt the stag and elk, to defend one's home, to compete in the great contests, these things are beautiful and good, and Amiria is their patron. Worshippers of the war god may be content to roll in the dust, punching and gouging, but your father was a great leader, and he fought like a king. Touching the sharp piece of amethyst, you wonder if you can live up to his legacy.
		*if father_gift = "talents for negotiation and scholarship"
			*set father_origin_specific "Apple tribe"
			*set father_born "The son of an Apple tribe farmer, Pon left the Northern Forest while still a boy to become a wandering scholar"
			*set clothing_design "a complex design of apples and pine trees"
			*set father_oath "the golden words of ${amiria}"
			*set invocation "the goddess of poetry"
			*set c_black_library true
			*set c_grand_academy true
			The desert capital of Shalmek has the Black Library. The Sea Kingdom city of Erethonia has the Grand Academy. But the Northern Forest has only wandering scholars, musicians, and counselors, who revered Amiria as the goddess not just of beauty but of poetry, wisdom, and the power to command. Though born a farmer of the Apple tribe, your father learned from those wandering poets how to act with dignity and honor–and how to crack a lock when necessary. Touching the sharp piece of amethyst, you remember your father's eloquence and wonder how you might compare.
	#A piece of garnet sacred to @{(mother_origin = "Desert") Mirak|Mithi}, the goddess of knowledge in the Desert Empire.
		*set wisdom +1
		*set father_origin "Desert"
		*if ( mother_origin = "Desert" ) and ( father_origin = "Desert" )
			*set mithi "Mirak"
		*set father_bead "a piece of garnet sacred to ${mithi}, the goddess of knowledge"
		*if father_gift = "engineering talent"
			*set father_origin_specific "Tel Bakir"
			*set father_born "The son of a potter from the desert city of Tel Bakir, Pon's natural intelligence earned him the chance to study craft and engineering from the city's magisters. But, after learning what he could, he soon left the grim city to make his fortune"
			*set clothing_design "the intricate lock-and-chain designs of the Bakiri artisans"
			*set father_oath "the oaths of the magisters"
			*set invocation "the magisters of Tel Bakir"
			Mirak (whom ${your_mother_and}the Northerners you grew up around call Mithi) is the goddess of all scholars, and your father was certainly a scholar. But he did not study at the Black Library in the capital. Born inside the walls of Tel Bakir, he learned the crafts of metal and the languages of the water clans among the harsh–some would say cruel–magisters of that grim city. He learned their traditional wisdom, then he fled that forbidding place to live as a free man. You touch the piece of garnet, which feels smooth and hard against your hand, and hope you have inherited some of your father's insight.
		*if father_gift = "prowess as a hunter"
			*set father_origin_specific "Fox clan"
			*set father_born "The son of a Fox clan lorekeeper, Pon abandoned the nomadic life when he saw the Black Library of Shalmek and petitioned for a chance to study there. Seeing his cunning and prowess, the scholars took him beneath the library and trained him in the sciences of geography and war"
			*set clothing_design "a pattern depicting the Black Library"
			*set father_oath "the Black Library"
			*set c_black_library true
			*set c_shalmek true
			*set invocation "${mithi}'s miraculous library"
			Your father was born to the Fox clan but soon settled in the great city of Shalmek, with its many gates and its Black Library. For Mirak (whom ${your_mother_and} the Northerners you grew up around call Mithi) is the goddess of applied knowledge as well as abstract philosophy: how to hunt man or beast across the desert, how to learn the secrets of your enemies, how to fight with cunning and skill. All these arts belong to ${mithi}, the goddess of knowledge, and your father learned them in the hidden rooms beneath her library. Feeling the smooth piece of garnet between your fingers, you wonder how you compare to him.
		*if father_gift = "talents for negotiation and scholarship"
			*set father_origin_specific "Nethara"
			*set father_born "The son of a wine seller in Nethara, that freewheeling Desert Empire city, your father petitioned for entrance to the Black Library of Shalmek. There he proved a gifted and cunning scholar"
			*set clothing_design "intricate designs of rivers and amphoras"
			*set father_oath "${mithi} the All-Seeing"
			*set c_black_library true
			*set invocation "the goddess of knowledge"
			Though born in the untamed oasis city of Nethara, your father soon left its revels for the wisdom of the Black Library. Settling in Shalmek, he proved a scholar and a diplomat, and despite his low birth, was soon counted among the wise and the clever. He must have been clever to negotiate with a priest of the god of knots! Feeling the smooth piece of garnet between your fingers, you wonder if you will ever be so cunning.
	#A tiny amulet sacred to Kadomis, worshipped in the Sea Kingdom as a god of courage and discipline.
		*set father_origin "Sea"
		*set resolve +1
		*set clothing_design "an elaborate labyrinth design"
		*set invocation "the god of war"
		*set father_bead "the hand-shaped amulet of Kadomis"
		*if father_gift = "engineering talent"
			*set father_origin_specific "Ikarius"
			*set father_born "The son of a poor net-maker in Ikarius, Pon drifted through many minor jobs before he proved himself as a guard in a rich merchant's house. He quickly moved up through the ranks, becoming an expert in security and siegecraft"
			*set father_oath "the invincible hand of Kadomis"
			Your father was born in Ikarius, one of the great cities of the Sea Kingdom. As a young man, he held many jobs and learned that relentless determination aided in whatever he did. To the Ikarians, who prize the security of their wealth above all other things, Kadomis is a god of locked doors and high walls. Of course, to make a good lock, one must learn how to open a bad lock, and your father's dedication aided him on both sides of Ikarius's high walls. Touching the hand-shaped amulet of Kadomis, you hope you inherited Pon's determination and discipline.
		*if father_gift = "prowess as a hunter"
			*set father_origin_specific "Peithia"
			*set father_born "The son of a poor Peithian fisherman, your father wanted to study war at the Tower of the Gauntlet in Peithia's capital, Tralcho, but was turned away for his low birth. Instead he became a caravan guard, then a marine, and proved himself an able warrior despite his lack of formal training"
			*set father_oath "the raised hand of Kadomis"
			Your father was a Peithian, born on a minor island far from the main city of Tralcho. He learned to hunt and fish as a boy and dreamed of traveling to Tralcho and training in the ancient war arts at the Tower of the Gauntlet. But Peithians of low birth are not welcome at the tower, and instead he made his own way, first as a caravan guard, then a marine. Touching the hand-shaped amulet of Kadomis, you hope you inherited your father's determination.
		*if father_gift = "talents for negotiation and scholarship"
			*set father_origin_specific "Mytele"
			*set father_born "The son of a Mytelean stonemason, Pon dreamed of becoming one of the elite Eleidian Guard, sacred protectors of the king. But he was too poor to afford the training and instead became one of Mytele's palace scribes. Nonetheless, he proved his worth to the queen herself and soon found himself promoted"
			*set father_oath "the raised hand of Kadomis and the throne of the great kings"
			*set c_eleidian_guard true
			Your father was born in the capital itself, Mytele, the Shrouded City. There he dreamed of becoming an Eleidian Guard, one of the disciplined protectors of King Hyras. The Eleidian Guards' power is the sign of Kadomis and his invincible shield. But though Pon had the discipline, he lacked the name, and instead become a minor scribe in the queen's service–a minor scribe renowned for his unwavering discipline and a sense of honor so pronounced it eventually brought him into the great king's presence. Touching the hand-shaped amulet of Kadomis, you hope you inherited your father's relentless determination.

*set has_necklace true
*set c_pon true
*set c_hareetha true

*if ( mother_origin = "Desert" ) and ( father_origin = "Desert" )
	*set phy "Faraam"
	*set yune "Jann"
	*set kadomis "Kesh"
	*set mithi "Mirak"
	*set amiria "Amri"
*comment Characters whose parents are both from the Desert Empire use its names for the gods.

You realize your mother has continued her story, through the ${clever_entrance}, past the trolls and divs that guarded Behemoth Mountain, to Hareetha herself and her ax, which bent the servitor races to her will. The story is always the same from here. The great storm that swept aside her army of monsters. Hareetha's death and her death-curse. The loss of King Vankred as the mountain crumbled, the mysterious disappearances of Heroch and the Golden Archer, the abduction of Zoriza. Col's grief and rage. The heavenly temples welcoming a new generation of greedy and venal disciples, as those who had fought in the war had almost all died. And then your parents' flight here, to a minor village of the Northern Forest.

Your father's death. Those were bitter years, though you were too young to remember. Para lapses into silence.

"I'm wasting your time," she says. "It is not yet dusk and I keep you here, trapped in my memories. Go outside and find your friend, that troll. Learn from what he teaches but do not trust him."

You try not to leap to your feet. Instead you rise, careful not to strike your head on the low beams, and push aside your mother's bow and ${mother_sword} sword to claim your…
*choice
	#Mantle–the traditional garb of young men in the forest tribes.
		*set has_mantle true
		*set gender "male"
		*set son_daughter "son"
		*set he_she "he"
		*set him_her "him"
		*set man_woman "man"
		*set boy_girl "boy"
		*set his_her "his"
		*set himself_herself "himself"
		*set lord_lady "lord"
		*set lordly_ladylike "lordly"
		*set priest_priestess "priest"
		*set priests_priestesses "priests"
		*set king_queen "king"
		*set pon_para "Pon"
		*set handsome_beautiful "handsome"
		*set gender_outfit "mantle"
		As is customary, you wear a blue-gray mantle with ${clothing_design} whenever you are outside. Though it provides scant protection against the cold of early spring, your mother says that the braids that hold it shut came from Col himself–the satyr who ended the Sun and Moon War and then matched wits against Acamon, the god of destruction.
	#Scarf–the traditional garb of unmarried Northern women.
		*set has_scarf true
		*set gender "female"
		*set son_daughter "daughter"
		*set he_she "she"
		*set him_her "her"
		*set man_woman "woman"
		*set boy_girl "girl"
		*set his_her "her"
		*set himself_herself "herself"
		*set lord_lady "lady"
		*set lordly_ladylike "ladylike"
		*set priest_priestess "priestess"
		*set priests_priestesses "priestesses"
		*set king_queen "queen"
		*set pon_para "Para"
		*set handsome_beautiful "beautiful"
		*set gender_outfit "scarf"
		As is customary, you wear a blue-gray scarf with ${clothing_design} whenever you are outside. A lady should never be without a length of cloth, for protection against the elements or if she needs to strangle a bandit. More important, your mother says that the fringe came from the gown of Zoriza herself–a girl during the Behemoth War, now monarch of the unified Desert Empire.
	#Shroud–the traditional garb in all three kingdoms of those neither men nor women.
		*set has_shroud true
		*set gender "nonbinary"
		*set son_daughter "child"
		*set he_she "they"
		*set him_her "them"
		*set man_woman "person"
		*set boy_girl "child"
		*set his_her "their"
		*set himself_herself "themself"
		*set lord_lady "effendi"
		*set lordly_ladylike "regal"
		*set priest_priestess "disciple"
		*set priests_priestesses "disciples"
		*set pon_para "your parents"
		*set handsome_beautiful "beautiful"
		*set gender_outfit "shroud"
		As is customary, you wear the elaborate shroud of the androgyne whenever you are outside. This intricate garb is antiquated outside the wild lands of the far Northern tribes or the water clans of the Desert Empire, but on the other hand, your mother says she took this shroud from the Golden Archer themself. Without their heroism, King Hyras would never have defeated Hareetha and her dark armies.

*set c_raun true
*set c_gronput true
*set c_hetch true

"Be wary of trolls, my ${son_daughter}!" Para calls as you shove open the wooden door to your house. "Today they come to trade, but yesterday they came to kill, enthralled by the dark ax Raun. Who can say what tomorrow might bring? They are not like people. Their souls are weak. They crave servitude, which is why we call them–"

The servitor races, yes, yes. But the dark ax is gone, and the trolls are free, and your friend Gronput is waiting for you. You race through Hetch, the village of the Pine tribe–or rather, the town, as it has tripled in size since your mother became chieftain and lured ${mother_contact} to this small community of artisans nestled deep in the woods. You run across the new bridge, which is tall enough that small boats can sail under it, and head for the forest and Gronput and the ruins of the Impossible Empire.

*page_break

You first met Gronput, the troll peddler, years ago during a particularly bitter winter, when the ice-winds flew down from Mount Ulgas. The old chieftain, believing the village cursed by a nymph, ventured into the woods and perished, crushed by a falling pine bough. Though your parents taught you well, you are no hero like them, and you made a mistake as a ${boy_girl} that nearly killed you.
*choice
	*if bearing = 2
		#I have never been charming. I quarreled with the bronzesmith's son. He beat me and left me in the woods.
			*set bearing 1
			*set fought_laikan true
			*set c_laikan true
			@{(might >= 3) You gave almost as good as you got in that brawl,|You fought as well as you could,} but Laikan was five years your elder, and as the youngest of seven brothers, he had no fear of anything. Especially after you insulted his mother, his father, and Pellocuno, his useless dog.

			You were not well liked, and when the redsmith's son left you, no one from the village came. But finally the troll peddler Gronput found you. He carried you to his firepit in an old ruin and warmed your freezing limbs. You still bear a scar on your cheek from Laikan's beating, but you kept all your fingers and toes and regained your strength.
	*if grace = 2
		#I'm somewhat clumsy. Traversing the treacherous old footbridge, I fell into the water.
			*set grace 1
			@{(wisdom >= 3) Now you consider yourself a ${man_woman} of above-average intelligence, but you were a foolish child.|You were a foolish child, and foolish, clumsy children often come to bad ends in the North.} When the rotten planks gave way, you hung on for as long as you could, then fell into the river. The thick ice saved you, as only your leg touched the swift-running water. But that was enough: you dragged yourself free and made it a dozen strides before you collapsed, freezing, in the snow. But you left a trail near a troll fishing hole, and Gronput found you and carried you to his firepit in an old ruin. He warmed your freezing limbs, and while your left leg remains a bit slow to this day, you survived.
	*if might = 2
		#I was frail and sickly as an infant, and the cold set into my bones, threatening to kill me.
			*set might 1
			Your early childhood was one of frequent illness.
			*if resolve > 2
				Only your furious will sustained you, for even as a small child, you were as stubborn as an old dog. But when
			*else
				When
			that winter came, you felt the cold reaching for your heart, and when your mother left to find the missing chieftain, you found yourself too weak to tend the fire. You tried to reach your neighbor's hearth, but in a delirium of exhaustion, you collapsed in the snow outside your house, hidden in the long shadows of the old wall. There you would have died, except that Gronput found you and carried you to his firepit in an old ruin. You are still frail, but you are strong enough to follow your indomitable mother, thanks to the troll.
	*if resolve = 2
		#I lack resolve and steadfastness. As a ${boy_girl}, I grew frightened when wolves howled and I hid in the freezing woods.
			*set resolve 1
			The wolves were miserable, starving creatures that winter, their howls more like frightened yips. But they sounded like the horned lions of Hareetha to you that night as you returned home from gathering firewood. @{(might >= 3) You probably could have grabbed a stout stick, even as a ${boy_girl}, and driven them away. Instead|Only a child and knowing you could not fight them off,} you hid. But as the cold grew more intense, you vacillated. Half of you wanted to flee to the safety of the village, the other half wanted to remain in the rising snow. Wracked by indecision, you realized too late that the cold had sapped your strength. You collapsed in the shadow of an ancient pine. There you would have died, except that Gronput found you and carried you to his firepit in an old ruin. That night still haunts your dreams, but the old troll saved your life.
	*if wisdom = 2
		#I am occasionally foolish and inattentive. I lost track of time and was trapped outside at night.
			*set wisdom 1
			You were never an attentive student. Neither was Para, but she has a cunning she inherited from ${mother_ancestors}. You were a foolish child, and as the snow fell, you lost your way. @{(grace >= 3) Even as you sprinted over the snow quick as a deer, you feared you would never see home again|You ran for home, but you did not know which way to turn}. Utterly lost, you struck a tree hard enough that it dropped its load of snow on you. There you would have died, had Gronput not found you and carried you to his firepit in an old ruin. You suspect you will never be a great scholar, but now you keep better track of time.

But Gronput did more than save your life. He introduced you to the marvels of Nepherine, the Impossible Empire. They are scattered all over the Northern Forest.

But the ruins are nothing you can recognize. That empire of philosophers and miracle workers must have lived in houses, worshipped the gods in temples, supplied their cities with aqueducts and wells, yet none of that remains. Only strange heaps of rubble, sometimes marked with images or abstract designs, litter the Three Nations. Seeing those ruins for the first time as Gronput's fire warmed your exhausted body, you marveled not just at the strange mosaics and broken writing, but at how none of the remaining pieces made any sense to you.

The remains of the Impossible Empire still make no sense, years later. As you reach the outskirts of the ruins, you slow and pull your blue-gray ${gender_outfit} close to protect yourself from the chill wind.

No one else comes here. No one else cares about a civilization that fell centuries ago. Only you and Gronput, and he only visits once per year, when his family passes through Hetch to trade.

"The first one!" Gronput shouts behind you. "The very first one—do you remember the sight?"

You remember the first mosaic that stopped you in your tracks.
*label mosaic_choice
*choice
	*hide_reuse #First, I think back to what I've learned about the Impossible Empire.
		Most of what you know from the Impossible Empire, you have pieced together with Gronput, working together to glean clues from the ruins or to learn from scholars and philosophers.

		Rising from the ashes of the world's near-destruction, the Impossible Empire began a millennium and a half ago as a philosophical academy far to the north. When these philosophers learned to access the Oricalchum, the vast machine powered by the labor of dark gods and damned souls that maintains the world, they unlocked the power of true philosophy.

		They used this true philosophy to travel instantaneously, to cure disease, and to build towering cities. The Impossible Empire flourished. But some dreamed of more; they wanted to repair the damaged world or to escape it.

		Seven hundred years ago, ambitious philosophers nearly freed the dark gods while meddling in the Oricalchum. When the prisoners tried to escape, the heavenly gods reacted with fury. They reimprisoned the dark gods and damned souls, then they permitted Acamon, the god of destruction, a minute on the surface. In that time, he utterly annihilated the Impossible Empire.
		*goto mosaic_choice
	*if bearing > 1
		#"A heroic general. I could see her glorious bearing and how she taught her soldiers to fight with swords and spears."
			*set mercy %-5
			*set favorite_mosaic "general"
			*set bearing +1
			*set warrior +1
			"Yes, you saw that general, so unlike the shabby warlords of today. But you remember also the impossible thing it depicted, don't you, Pon Para?" Gronput says. "The voice became like a hundred voices, the woman's helmet, a hundred helmets, and her sword like a hundred swords."

			The strangeness of it filled you with wonder, but the general filled you with admiration. They followed her because she knew the art and science of battle. The sight compelled you to learn how the Impossible Empire fought, for though its soldiers employed many wondrous weapons, it still relied on swords and spears to win the day–and the mosaics showed you exactly how to fight with them.
	*if wisdom > 1
		#"A physician treating a wounded man. She held strange medical devices, one in each hand."
			*set mercy %+10
			*set wisdom +1
			*set physician +1
			*set favorite_mosaic "physician"
			"Yes, you saw right away the truth, Pon Para," Gronput says. "Too many wounds! The man had too many, like a man who fell beneath hooves. But the healer, she smiles–little arrogant smile, like when I get a good deal and your mother does not, right? And the man…what is the word?"

			You remember the wounded man's expression. Not horrified at his injuries–more embarrassed by them. There was no fear on his face.

			"And you said, because you knew right away, 'Troll who saved me, that is impossible.'"

			After that first meeting with Gronput, you sought out every mosaic you could find that showed people being healed and cured and put back together. You learned as much as you could from those images, and while you could never understand the wand of lightning or the sword made of blood or the goblet full of tears, or what they did, you learned how people were put together, inside and out.
	*if might > 1
		#"Strong mountaineers armed with tools for climbing and leaping."
			*set might +1
			*set athlete +1
			*set favorite_mosaic "mountaineers"

			"Yes, you saw the things on their feet and hands, Pon Para," Gronput says. "But also the images that showed men and women with nothing but their clothes, and the ways they knew how to climb and leap. For many pictures, they showed impossible things. A rope that is twenty ropes. A woman who becomes a wheel and flies above a mountain."

			The impossible things were astounding, but you had better luck understanding the regular depictions, full of clever tricks: how to move your body to avoid strain or injury, how to climb and jump. You learned everything you could.
	*if grace > 1
		#"Their ships and how they tied their lines. The artists drew each finger, and I could follow each gesture and movement."
			*set grace +1
			*set mariner +1
			*set favorite_mosaic "ships"
			"Yes, you saw right away the truth, Pon Para, but then the truth behind the truth," Gronput says. "The vessels, they were impossible. Some had no sails, or too many, or no oars, or oars for walking on land. But the…the rules? They were the same."

			Even as a child, you grasped that the principles of knotwork were the same for the Impossible Empire's sailing vessels as for the Pine tribe's. The mosaics of the Impossible Empire could teach you almost as much as your father could about boats and lines, and more than that, they showed you how to move swiftly and cleanly. And you began your study.
	*if resolve > 1
		#"Mountain hermits worshiping the heavenly gods. Their resolve showed on their faces, their traditional piety in the tools they held."
			*set innovation %-10
			*set resolve +1
			*set priest +1
			*set favorite_mosaic "hermits"

			"Yes, you saw their holiness, Pon Para," Gronput says, "and knew they worshipped the five heavenly gods. Not like us, eh? Not like trolls. They choose to serve, those holy people. But you say right away, pointing at their hands, what are those tools, and I tell you, those are impossible things. So you forget them and concentrate on their great holiness. The determination of the people to be holy, you concentrate on that."

			And you learned everything you could, for while their impossible tools told you nothing, you studied their gestures, their holy dances, everything the mosaics depicted. You even decided on your favorite deity. You wonder what your mother would think of someone so young making that choice.

You turn to look at Gronput. The troll stands on an irregularly shaped pillar covered in intricate, incomprehensible knotwork. The substance of the pillar is neither metal nor stone. Gronput is an old troll, his hairy body gray all over, the muzzle of his little vulpine face almost white, though his teeth and eyes are still sharp. Like all trolls, he is small and fast and fragile-seeming, with little backward-curving horns. Trinkets for sale clatter on his wide belt. It is hard to imagine these creatures in their teeming thousands, armed with spears of fire-blackened wood, standing fearlessly against your parents and the other heroes of the Behemoth War.

Yet there is something different about Gronput this year. His eyes seem fever bright, his expression wild. His lips curl involuntarily back in a snarl, as if he has seen something terrible. He looks afraid. You have never known the jolly, contented old peddler to show a trace of fear, even when haggling with your mother–and everyone is afraid of her.

*temp word_type "some kind"
*choice
	#"Gronput, what troubles you? Let us take counsel together." We have always been honest and patient with one another.
		*set honesty %+10
		*set command %-10

		*if bearing = 1
			Though you have never been charming by human standards, Gronput has always listened to you.

		The gleam of madness in Gronput's eye vanishes as soon as he sees your worried expression.

		*label gronput_sorry

		"I am sorry, Pon Para," he says. "Long journey. Just a long journey between cities, making the great circle my family makes. I lost many sons-of-sons. There is nothing else."

		There is something else,
		*if bearing > 2
			and you think that you could get Gronput to open up with enough time and ${word_type} words.
			*goto give_name
		*elseif wisdom > 2
			and you think you could figure out what if Gronput will stay and speak.
			*goto give_name
		*elseif resolve > 2
			and you think your patience, determination, and ${word_type} words could in time convince Gronput to speak.
			*goto give_name
		*else
			but you have no idea how to get Gronput to say more.
			*goto give_name
	#"The servitor races should know better! By ${father_oath}, tell me why you act this way."
		*set innovation %-10
		*set command %+10
		*set word_type "the correct"

		*if bearing = 1
			Though you have never been authoritative by human standards, Gronput has always respected you.
		The gleam of madness in Gronput's eyes vanishes as soon as you invoke ${invocation}. A young troll might scoff at the obligations of the servitor races, but Gronput never would.
		*goto gronput_sorry
	#I bare my teeth right back. Gronput is my elder and I should honor him, but I will not be threatened.
		*set mercy %-15
		*if bearing = 1
			Though you have never had much presence by human standards, Gronput has always respected you.
		The gleam of madness in Gronput's eyes vanishes as soon as he realizes you will not lower your gaze. He shakes his head, then rubs his furry face.
		*goto gronput_sorry

*label give_name

*temp parent_lands "undetermined"
*if mother_origin = father_origin
	*if mother_origin = "Desert"
		*set parent_lands "Desert Empire"
	*if mother_origin = "Forest"
		*set parent_lands "forest tribe"
	*if mother_origin = "Sea"
		*set parent_lands "Sea Kingdom"
*if mother_origin != father_origin
	*if ( mother_origin = "Desert" ) and ( father_origin = "Forest" )
		*set parent_lands "Desert Empire or forest tribe"

	*if ( mother_origin = "Desert" ) and ( father_origin = "Sea" )
		*set parent_lands "Desert Empire or Sea Kingdom"

	*if ( mother_origin = "Forest" ) and ( father_origin = "Desert" )
		*set parent_lands "forest tribe or Desert Empire"

	*if ( mother_origin = "Forest" ) and ( father_origin = "Sea" )
		*set parent_lands "forest tribe or Sea Kingdom"

	*if ( mother_origin = "Sea" ) and ( father_origin = "Desert" )
		*set parent_lands "Sea Kingdom or Desert Empire"

	*if ( mother_origin = "Sea" ) and ( father_origin = "Forest" )
		*set parent_lands "Sea Kingdom or forest tribe"

"But," the old troll says, "I am still calling you by your little ${boy_girl} name, and you are a ${man_woman} grown, are you not? What are you called now?"

*choice
	*if ( gender = "male" ) and ( father_origin = "Desert" )
		#"Zurad."
			*set name "Zurad"
			*set innovation %-5

	*if ( gender = "male" ) and ( father_origin = "Desert" )
		#"Arashir."
			*set name "Arashir"
			*set innovation %-5

	*if ( gender = "male" ) and ( father_origin = "Forest" )
		#"Borinn."
			*set name "Borinn"
			*set innovation %-5

	*if ( gender = "male" ) and ( father_origin = "Forest" )
		#"Cronn."
			*set name "Cronn"
			*set innovation %-5

	*if ( gender = "male" ) and ( father_origin = "Sea" )
		#"Olesso."
			*set name "Olesso"
			*set innovation %-5

	*if ( gender = "male" ) and ( father_origin = "Sea" )
		#"Coromedes."
			*set name "Coromedes"
			*set innovation %-5

	*if ( gender = "male" ) and ( mother_origin = "Desert" )
		#"Faranid."
			*set name "Faranid"
			*set innovation %-5

	*if ( gender = "male" ) and ( mother_origin = "Desert" )
		#"Garumandar."
			*set name "Garumandar"
			*set innovation %-5

	*if ( gender = "male" ) and ( mother_origin = "Forest" )
		#"Shol."
			*set name "Shol"
			*set innovation %-5

	*if ( gender = "male" ) and ( mother_origin = "Forest" )
		#"Admer."
			*set name "Admer"
			*set innovation %-5

	*if ( gender = "male" ) and ( mother_origin = "Sea" )
		#"Phion."
			*set name "Phion"
			*set innovation %-5

	*if ( gender = "male" ) and ( mother_origin = "Sea" )
		#"Vorus."
			*set name "Vorus"
			*set innovation %-5

	*if ( gender = "female" ) and ( father_origin = "Desert" )
		#"Zarina."
			*set name "Zarina"
			*set innovation %-5

	*if ( gender = "female" ) and ( father_origin = "Desert" )
		#"Seili."
			*set name "Seili"
			*set innovation %-5

	*if ( gender = "female" ) and ( father_origin = "Forest" )
		#"Divona."
			*set name "Divona"
			*set innovation %-5

	*if ( gender = "female" ) and ( father_origin = "Forest" )
		#"Tesumin."
			*set name "Tesumin"
			*set innovation %-5

	*if ( gender = "female" ) and ( father_origin = "Sea" )
		#"Elco."
			*set name "Elco"
			*set innovation %-5

	*if ( gender = "female" ) and ( father_origin = "Sea" )
		#"Pendathi."
			*set name "Pendathi"
			*set innovation %-5

	*if ( gender = "female" ) and ( mother_origin = "Desert" )
		#"Adamashtis."
			*set name "Adamashtis"
			*set innovation %-5

	*if ( gender = "female" ) and ( mother_origin = "Desert" )
		#"Nesrin."
			*set name "Nesrin"
			*set innovation %-5

	*if ( gender = "female" ) and ( mother_origin = "Forest" )
		#"Aila."
			*set name "Aila"
			*set innovation %-5

	*if ( gender = "female" ) and ( mother_origin = "Forest" )
		#"Miobel."
			*set name "Miobel"
			*set innovation %-5

	*if ( gender = "female" ) and ( mother_origin = "Sea" )
		#"Phylaxa."
			*set name "Phylaxa"
			*set innovation %-5

	*if ( gender = "female" ) and ( mother_origin = "Sea" )
		#"Unethia."
			*set name "Unethia"
			*set innovation %-5

	*if ( gender = "nonbinary" ) and ( father_origin = "Desert" )
		#"Zurad."
			*set name "Zurad"
			*set innovation %-5

	*if ( gender = "nonbinary" ) and ( father_origin = "Desert" )
		#"Seili."
			*set name "Seili"
			*set innovation %-5

	*if ( gender = "nonbinary" ) and ( father_origin = "Forest" )
		#"Borinn."
			*set name "Borinn"
			*set innovation %-5

	*if ( gender = "nonbinary" ) and ( father_origin = "Forest" )
		#"Tesumin."
			*set name "Tesumin"
			*set innovation %-5

	*if ( gender = "nonbinary" ) and ( father_origin = "Sea" )
		#"Olesso."
			*set name "Olesso"
			*set innovation %-5

	*if ( gender = "nonbinary" ) and ( father_origin = "Sea" )
		#"Pendathi."
			*set name "Pendathi"
			*set innovation %-5

	*if ( gender = "nonbinary" ) and ( mother_origin = "Desert" )
		#"Faranid."
			*set name "Faranid"
			*set innovation %-5

	*if ( gender = "nonbinary" ) and ( mother_origin = "Desert" )
		#"Adamashtis."
			*set name "Adamashtis"
			*set innovation %-5

	*if ( gender = "nonbinary" ) and ( mother_origin = "Forest" )
		#"Shol."
			*set name "Shol"
			*set innovation %-5

	*if ( gender = "nonbinary" ) and ( mother_origin = "Forest" )
		#"Miobel."
			*set name "Miobel"
			*set innovation %-5

	*if ( gender = "nonbinary" ) and ( mother_origin = "Sea" )
		#"Phion."
			*set name "Phion"
			*set innovation %-5

	*if ( gender = "nonbinary" ) and ( mother_origin = "Sea" )
		#"Unethia."
			*set name "Unethia"

	*if choice_randomtest = false
		#"I did not choose one of the old ${parent_lands} names, but rather…"
			*set innovation %+5
			*input_text name

*set name_defined true
*temp good_name "scholar"
*if naturalist > 0
	*set good_name "hero"
"${name}," Gronput says. "I like it. It is a good name for a ${good_name}. Trolls, of course, must earn their names. I am called Gronput because…"

Then the old troll's muzzle twitches, and his lips peel back again, as if he smells carrion. He looks around, but there are only the ruins. Crows suddenly take flight and rise, cawing, before they disappear over the eastern hills.

"Have you seen anything in these woods, Pon Para?" the troll asks. His expression is vague and unfocused.

There are many strange things in these woods. Gronput is thinking of something in particular, but you do not know what.
*choice
	#Maybe I can try clever, leading questions. "I have noticed some odd things. Do you mean…the noises?"
		*set honesty %-15
		*temp war_number "quite a few"
		*if wisdom = 1
			*set war_number "at least two"
		*if wisdom > 2
			*set war_number "over a dozen"

		"Yes, the voices!" Gronput howls. "There are things in the woods, and they whisper to one another and to their mistress. The witch is awakening! I think they are calling to me, telling me to renew the ancient war."

		Which ancient war? You can name ${war_number}, including the Sun and Moon War and the one your parents fought in.
		*label but_before
		But before you can learn more, Gronput howls again, his voice like a wild animal's. Then he leaps off the ruin like a far younger troll and scampers madly into the woods!
		*goto follow_gronput
	#I'll try something new: the stoic techniques of the Erethonian sophists. "Tell me about this worry you have. Is it a problem we can solve now, or not?"
		*set innovation %+15
		*temp pel_lore ""
		*if wisdom > 1
			*set pel_lore ", though you know that the god who made the trolls was Pel, the god of thieves, and nothing good ever comes from him"
		"By the god that made me," Gronput howls, "I can! I can silence them! I can silence them forever! The witch is awakening, and her servants hunt these woods, but I will stop them!"

		The witch? You don't know who that could be${pel_lore}.
		*goto but_before
	#I fear Gronput has stumbled into something unholy. "In the name of ${yune} and ${phy}, shake off this terror, old friend!"
		*set innovation %-15
		Once again, lucidity floods Gronput's face, but it vanishes even more quickly this time. "Yune and Phy, king and queen!" And he spits twice. "Pel made me, Pel down in his prison. But I hear the whispers, and I can silence them forever! The witch is awakening, and her servants hunt these woods, but I will stop them!"
		*goto but_before
	#Gronput seems so frail right now. I need to get him off that ruin before he hurts himself.
		*set mercy %+15
		You reach your hand out to Gronput, but he recoils as if you're offering him poison.

		"You're part of this, ${boy_girl}! You're just like the others. Do you know her? Have you seen the witch? I have not seen her, but I hear her whispers! Whispers I plan to silence forever!"
		*goto but_before

*label follow_gronput

*choice
	*if bearing != 1
		#I call after him, confident that my commanding tone will stop Gronput in his tracks.
			*set command %+10
			Gronput smashes through the underbrush, splashing through muddy puddles and breaking sticks.
			*if ( bearing > 2 ) or ( diplomat > 0 )
				*set clue_1 true
				*set bearing +1
				*set priest_renown +10
				*set c_philosophy true
				But your voice cuts through his panicked flight. You hear him freeze somewhere just out of view, screened by dead trees.

				He clears his throat. You can almost see his throat working, the way a person might work up to an apology. But he says only, "We did not take her! Philosophy took her!"

				And then he's running again, too swift for you to follow. But you feel as if you just learned something–not from the words, which you don't understand. But you understand now how to make people obey with only the tone of your voice. Even a mad troll stopped short when you spoke.

				Gronput stopped but did not return. You fear the worst. Searching for any sign of him, you find only his peddler's trinkets, abandoned in the snow.
				*goto conclusion
			*else
				*set bearing +1

				You shout after him, but it's worthless; he's already gone. But even as Gronput flees, stumbling, through the underbrush, you understand your mistake and realize how to pitch your voice to make someone freeze in their tracks. Your father had the trick of it, and suddenly you understand what he did.

				But you fear this knowledge of yours may come too late for your friend. Searching for any sign of him, you find only his peddler's trinkets, abandoned in the snow.
				*goto conclusion
	*if grace != 1
		#I sprint through the woods after him, using all my speed and athletic training. I can outrun Gronput, then take him by surprise.
			*set honesty %-10
			*if ( grace > 2 ) or ( athlete > 0 )
				*set trickster_renown +10
				*set grace +1
				*set clue_1 true
				You run. And suddenly you're running more swiftly than you ever have before, swifter than your mother ever managed across the Western Desert to confront Hareetha. Your sandals sink into the cold, muddy ground, but nothing can hold you, nothing can slow you down. A crevasse looms before you, and you leap, clear the distance, then race down a scree-covered slope.

				Right in front of Gronput.

				The troll screams and backs away, swatting at the air with his little black claws. He's clearly humbled by your speed and cleverness, and he babbles in his native language, then shouts something in yours–though you still do not understand: "We did not take her! Philosophy took her!"

				But then his eyes grow bestial again, and he dives away from you, vanishing into another slope. He wriggles into a burrow, leaving his cheap tools and trade goods behind, and vanishes. You examine the burrow, but you could never fit.

				You catch your breath, aware that you have learned something in this pursuit. You feel that you have learned something about the hunter, something mere footraces as a child could never have taught you. But you were not swift enough to catch Gronput, and now who knows where he has gone?
				*goto conclusion
			*else
				*set grace +1
				*temp breathing "breathing hard"
				*if might = 1
					*set breathing "gasping for breath"
				*if might > 2
					*set breathing "breathing deeply"
				You run and manage to stay right behind Gronput. But then he drops down on all fours and sheds his peddler's trinkets. You leap over a copper tool, and your sandal sinks into mud. That momentary delay spoils your pursuit; in seconds, Gronput has vanished into the woods, quick as a fox. You follow his trail to a burrow too narrow for you to enter.

				Nonetheless, while ${breathing}, you realize you have learned something about the pursuit, something childish footraces alone could not teach you. You feel swifter and more energetic. Still, you were not swift enough to catch Gronput, and now who knows where he has gone?
				*goto conclusion
	*if might != 1
		#I follow over the rough terrain, then use my knowledge of wild places to climb up a hill and get in front of Gronput.
			*if ( might > 2 ) or ( naturalist > 0 )
				*set hero_renown +10
				*set might +1
				*set clue_1 true
				Gronput's desperate flight slows as you fall behind, but you're only biding your time, jogging with steady and relentless determination toward a low, rocky cliff. You pull yourself up the cliff face, feeling the strength in your limbs and full of confidence, then leap onto the higher level just as Gronput stumbles up the slope.

				He stops, mouth parted in surprise to reveal sharp teeth. Then he shouts something you do not understand, though he speaks your language: "We did not take her! Philosophy took her!"

				He dives down and wiggles into a burrow, leaving his cheap tools and trade goods behind, and vanishes. You examine the burrow, but you could never fit.

				Still, breathing easily, you feel that you have learned something today about the extent of your strength, something mere wrestling games as a child never taught you. But this newfound understanding of your power may have come too late for Gronput.
				*goto conclusion
			*else
				*set might +1
				You maintain a steady pace behind Gronput, but then he drops down on all fours, shedding his peddler's wares, and moves like an animal through the underbrush. You soon find yourself winded, even as the old troll races through the trees, driven by some unholy impulse. At last you're forced to admit that you've lost him.

				Nonetheless, you're breathing deeply but not gasping for breath, and you realize that you have learned something today about the limits of your endurance, something mere physical labor could not teach you. You feel stronger and, more than that, more sure of your strength. If only you could have reached Gronput.
				*goto conclusion
	*if wisdom != 1
		#I listen carefully to Gronput's crashing flight and follow his trail, then reach him using old paths the troll does not know.
			*if ( wisdom > 2 ) or ( scholar > 0 )
				*set clue_1 true
				*set wisdom +1
				*set sage_renown +10
				*set innovation %-10
				*set c_philosophy true
				Gronput's initial flight is desperate but easy to follow. Thinking he may have lost you, he slows and starts to mutter to himself, loud enough for you to hear the words that aren't in troll-speak: "We did not take her! Philosophy took her!"

				The rants of a madman, or important words you lack the context to understand? Consideration will have to wait, as you continue to follow the troll through the woods, using paths your father showed you on old maps. When you're sure you have him, you step out into a clearing, only to find Gronput gone and his peddler's wares scattered on the ground. You soon discover a tunnel too narrow for a human. The troll must have disappeared into it like a badger.

				[i]We did not take her. Philosophy took her.[/i]

				Though you could not catch Gronput, you have learned something about your own senses. They are perhaps the keenest in the village, and not just through natural ability; though your pulse is still pounding in your ears, you feel that you have learned to hone and focus your senses, to listen, to take information in and to consider it wisely. Nonetheless, you fear your understanding may have come too late for Gronput.
				*goto conclusion
			*else
				*set wisdom +1
				*set innovation %-10
				Gronput's initial flight is desperate but easy to follow. You hear him crashing ahead of you, spot his clawed footprints in the mud and the snow. But then, unexpectedly, he eludes you. You double back and discover his peddler's trinkets scattered about, and then find an old burrow too narrow for any human. Gronput must have clawed his way underground.

				A defeat–but not a total one. You have learned something about your senses and their limits, something you could not have learned hunting small game in these woods. You feel more keen, more attuned to the world around you. If only that newfound understanding could have been enough to stop Gronput.
				*goto conclusion

*label conclusion
*set character_set true
*set gronput_mad true
*set has_gronput_trinkets true
*temp people_voices "polite but disinterested"
*if bearing = 1
	*set people_voices "occasionally polite, sometimes jeering"
*if bearing > 2
	*set people_voices "polite and friendly"

The last of the light fades in the west, turning the trees black and the sky purple-red. You retrieve Gronput's scattered trinkets, wrapping them carefully in your ${gender_outfit}, then find the road and head back toward Hetch before the first stars appear. People call to you, their voices ${people_voices}. You pay them no mind.

*if clue_1
	The words echo in your mind: "We did not take her! Philosophy took her!"

A witch in the woods. An old friend driven to distraction, perhaps madness. Even you feel it: some change in the air. The night winds are bitter, and you know this spring will not be like the others.

*finish