*comment Here's your opportunity to opt out, Player. I'm not the one offering it to you. Don't you see now? The choice was only ever yours. 
*hide_reuse 
*temp NPC false 
*temp maria_pick true
*temp joshy_pick true
*temp tommy_pick true
*temp catrina_pick true 
*temp options 0 
*temp loop 0 
*temp like_attention false 
*check_achievements comeout 
*if choice_achieved_comeout
	*set Cat "Cat"
	*set ce "he"
	*set ceir "his"
	*set cem "him"
	*set cemself "himself"
*text_image chap_1.png center Level 1: An Entanglement of Friends

*if choice_randomtest
	*achieve ending
	*achieve second_ending
*check_achievements ending second_ending 
*if choice_achieved_ending
	Sure, you were given the opportunity to turn back. You can see that now. A chance to give up, get out, get away—whatever you want to call it. It, this: to save yourself, your friends. To opt out of the game. 

	Remember? 

	You chose not to, of course. What kind of player would you have been if you had chosen not to play? No player at all, that's what kind. A player is what a player does. You know? And what does a player do? A player plays. It's as simple as that. 

	Later, the game will say this was part of its rules; every game has them. People often think that rules are only for players, but that's incorrect. The game has to follow the rules, too. For the game to exist, for it to be valid (whatever that means), it has to offer players the option to quit early on. Like, really early on. In the prologue. Before you even hit @{choice_achieved_second_ending restart|start}. 

	And it did, didn't it? 

	But nobody ever said no. You see? 

	*if choice_achieved_second_ending 
		Again and again, we said yes. Yes, yes, I'll play. 
	*else 
		We all had to play. 
	*page_break
The convenience store is doused in bright white light, turning the windows into mirrors. You have the night shift again. The whirring of the refrigerators and the droning murmur of the fluorescent lights above have a hypnotic effect on you. It's almost meditative. If you're into that sort of thing. 

Outside, everything is dark. Even the single street light is out. It's a quiet night at the beginning of February—not that it makes a difference; it seems to you that all the nights are quiet, in this nothing town, this nothing place. Sometimes you wonder why the store remains open 24/7. They don't pay you much, but so few customers ever show up at night it can't possibly make sense. Like, from a financial point of view.  

Working the night shift means you get off work at 6 a.m., and school doesn't start until 8.15 a.m. If you time it right, you might even be able to squeeze in an hour of sleep. 
*choice 
	#It hardly seems worth the trouble. 
		*set chaotic %+mid_change
		*set sleepdeprived true 
		Besides, sometimes you find that sleeplessness puts you in an interesting state of mind. Yields strange thoughts. 

		And you need strange thoughts, these days. It's the kind of thing that can give you a certain edge. 
	#I have no trouble sticking to a tight schedule. 
		*set chaotic %-mid_change
		It's important to keep yourself sharp and orderly. When everything around you is unpredictable and chaotic, you have to be your own constant. Especially now, with the strange odds you're facing. 
	#I'm fine. Don't need much sleep anyway. 
		*set brave %+mid_change
		*set sleepdeprived true 
		Or at least that's what you tell yourself and everyone around you. You're the strong one, the dependable one. You can face any odds and never lose your nerve. 

		Right? 
	#I better get as much sleep as I can. Might need it. 
		*set brave %-mid_change 
		It's best to be prepared, cautious, hedge your bets. Especially with the kind of strangeness you're facing. You never know what will be demanded of you. 

*check_achievements eldritch
You glance at your backpack. Feel the urge to reach inside, check the game again. Run your fingers along its black sides, wonder at the @{choice_achieved_eldritch strange smell, the slightly slimy residue it always leaves behind|material it's made of—too smooth to be plastic, too light to be metal}. See if new instructions have popped up on its dark green screen. 

But you don't. Because your supervisor is standing in front of the cash register and staring you down. It's obvious he doesn't like you. He tolerates you, if that. 
*choice 
	#I feel small. I hate being the center of attention. 
		*set self_centered %-mid_change 
		Sometimes you wish you could be invisible.  

		Sometimes you think you've got the art of self-effacement down so well that you believe you can actually make yourself disappear. 
	#I stare right back. I like being the center of attention. 
		*set self_centered %+mid_change 
		*set like_attention true 
		If he doesn't like what he sees, that's his problem, not yours. 
	#Who cares what he thinks? Rules are for losers. 
		*set chaotic %+mid_change 
		Other people's impressions of you don't concern you. Why would they? That's their business, not yours. Besides, you can't control what other people think. You can hardly control your own thoughts. 
	#I become self-conscious. Is something wrong with my uniform?
		*set chaotic %-mid_change
		Indeed, there is. Your name tag is askew. Oh, God.

		You rush to fix it as your supervisor disappears into the back room. 

		How could you let this happen? You're usually so careful. 
		*goto tag

"Fix your name tag," your supervisor says. 

You look down and realize your badge is askew. You unpin it from your uniform. 

Your supervisor gives you another stern look before disappearing into the back room, where he will pretend to work—on orders, budgets, whatever it is he does—but really you know he'll just nap until morning. 
*label tag

You look at your badge for a moment before pinning it to your lapel again. 

It reads, in fake handwriting, "Hi! I am" and then, in your actual handwriting, your name follows:
*choice 
	#"Sam."
		*set name "Sam"
	#"Ashley."
		*set name "Ashley"
	#"Jordan."
		*set name "Jordan"
	#"Carson."
		*set name "Carson"
	#"Alex."
		*set name "Alex"
	#Something else. 
		*label name_input
		What is your name?
		*input_text name
		*set name "$!{name}"
		So your name is "${name}." Is that right?
		*choice
			*allow_reuse #Yes.
			*allow_reuse #No. 
				*goto name_input

Then, your pronouns follow:
*choice
	#"He/him."
		*set e "he"
		*set eir "his"
		*set em "him"
		*set eirs "his"
		*set emself "himself"
	#"She/her."
		*set e "she"
		*set eir "her"
		*set em "her"
		*set eirs "hers"
		*set emself "herself"
	#"They/them."
		*set e "they"
		*set eir "their"
		*set em "them"
		*set eirs "theirs"
		*set emself "themselves"
		*set plural true 
	#Something else. Let me spell them for you.
		*label pronouns
		Please enter the equivalent of "he/she/they."
		*input_text e
		Please enter the equivalent of "his/her/their."
		*input_text eir
		Please enter the equivalent of "him/her/them."
		*input_text em
		Please enter the equivalent of "his/hers/theirs."
		*input_text eirs
		Please enter the equivalent of "himself/herself/themselves."
		*input_text emself
		Is your pronoun singular or plural?
		*choice
			*allow_reuse #Singular.
			*allow_reuse #Plural.
				*set plural true
		Okay. Your pronouns are: ${e}/${eir}/${em}/${eirs}/${emself}. Are these correct? 
		*choice
			*allow_reuse #Yes.
			*allow_reuse #No. 
				Okay, no problem. Let's try this again. 

				*goto pronouns

*check_achievements ending 
Right, so the other good thing about the night shift (wait, what was the first good thing?) is that you have ample time to kill, which means ample time to do what you love best: 
*choice 
	#Draw. 
		*set insight %+hi_change
		*check_achievements ending 
		You started when you were little. Drawing, painting, anything that leaves a mark on a surface—you've loved it all for as long as you can remember. You could make up a backstory here, about that favorite uncle/grandmother/schoolteacher who pressed an expensive sketchpad and a bunch of good pencils into your hands one Christmas/birthday/whatever holiday you most cherish now that you're almost, almost an adult, and told you to find your voice, be yourself, express what's in the dustier corners of your weird little heart. 

		Or maybe you just picked up a napkin and a cheap ballpoint pen you found in a drawer and started drawing one day. 

		And you were good at it. Very, very good. You're not good at many things—your mom sure keeps reminding you of that—but you were good at drawing. 

		Tonight, it's a self-portrait. 
		*if choice_achieved_ending
			Describe it to me, Player. Or at least pretend. 

			Here, like this: 

			It's charcoal 
		*else 
			Charcoal 
		on sepia, your most recent obsession. You've done so many of these, you even dream in sepia these days. @{sleepdeprived When you actually manage to catch some sleep.|}

		This one is turning out a little strange, though.
		*choice
			#My eyes are too big. 
				*set bigeyes true 
				Not just big for the drawing; proportion is not the problem here, and you're too skilled to make that kind of mistake. This is something else. They look uncanny, like the eyes of something alien, barely human. Too wide, too open, too seeing. 
			#My face doesn't feel like my own.
				*set not_my_face true 
				You wonder sometimes, do other people ever feel this way? Do they look in the mirror and fail to recognize themselves? Who is this stranger that wears your skin, bears your name, goes to your school? 

				Only the eyes are the same. 
			#My face is a black hole. 
				*set blank true 
				You managed to get every detail of your hair right, the texture of your skin, the shape of your ears. But your face is null, a nothingness. A dark smudge. 

				You can't decide if what you're drawing is an opaque, impenetrable surface, or the unfathomable depths of an abyss. Something that traps the light, and so becomes unseeable. 
		
		But you like it, anyway. It works. Whether anyone else would think so is not your concern. Besides, how would you ever know? Even if they tell you they do or they don't, there's no way to be absolutely, one hundred percent sure they're being truthful. 
	#Play video games.
		*set hobby 2
		*set athletics %+hi_change
		*check_achievements ending 
		You reach into your backpack. Your hand hovers over the game for a moment, but you hold back, pull out your handheld console instead, and slip in one of your brightly colored cartridges. 

		As soon as the screen chirps alive, you turn the volume down—don't need your supervisor giving you another of those looks. But the familiarity of the tune calms you immediately, like this is a safe space, and like nothing could ever hurt you while you play. 

		*if choice_achieved_ending
			By now, of course, you know that's a dangerous thing to think. It lowers your defenses. Leaves you vulnerable. Gaming is anything but safe. At least here, at least now. At least for you and your friends. 
			*page_break
		You can't remember how young you were when you got hooked on video games. There wasn't much variety back then; it was either a ball bouncing on a moving platform across a black screen or a triangle that your imagination changed into a spaceship shooting at hordes of enemy crafts. But it was enough. 

		Tonight, though, you're playing your favorite. Your guilty little pleasure called:
		*choice 
			#@{choice_nightmode Night|Afternoon} of the Knight. 
				*set knight true
				It's your basic RPG, where you play a knight whose goal is to save a princess locked away in a castle. In order to do so, you need to hack through fields upon fields of overgrown thornbushes, practically forests of the things. You start out with a basic wooden sword (how that's supposed to hack through anything has always been beyond you) and upgrade as you go. 

				Except you never find out who that princess is, why she was locked away, or why you need to save her. The game doesn't make that explicit, but you know by now that, in order for the game to be won, you need to decide what your motivation is on each playthrough. Do you want to save the princess for money? For glory? For love? To fill the dark hole in your heart, to muffle that little voice that always tells you you're too small, too insignificant, not good enough? Unless you know your reasons for hacking through those branches and letting those forests of thorns rip your arms to shreds, the game won't be satisfying.

				You also meet a bunch of NPCs along the way that invite you to undertake side quests and challenges, or simply offer advice to help you on your way, presumably out of the kindness of their hearts. 
				*choice 
					#I usually go for these. 
						*set brave %+mid_change
						You 
						*label knight_continue
						usually go for these quests and trust the advice you're given—occasionally to your detriment, not to mention that of the princess. You find people have been deceitful, which greatly disappoints you. Here you are, trying to be brave, trying to be useful, only to have people throw it back in your face and try to take advantage. You want to shout at them then, "BUT I WAS ALREADY HELPING! WHAT MORE DO YOU WANT?" There's no one to shout at, though, except pixels on a screen. Whenever this happens, you think back on those NPCs' portraits and wonder if there was something in their faces that you should have seen, some element of physiognomy that should have tipped you off. 
						*if chaotic >= stat_mid_pass 

							You know better, of course. The world is not as neat as that, and not everything can be anticipated. You can't be prepared for everything. You can only do your best, however chaotic the circumstances. 

							And then hope the game is winnable. 
						*else 
							Because there must have been a clue, right? That's only fair. A clue would allow you to take responsibility for your mistake in failing to spot whatever it was that would have given you a better outcome. Otherwise, the world is chaos, and nobody can do a thing about it. 

							But games are fair. It's what makes them winnable. And that's what makes them worth playing. 
					#I am always suspicious of these.
						*set brave %-mid_change 
						You are always suspicious of these. Because you know no one does anything without some kind of gain to win. Everyone has an agenda; even self-sacrifice, the greatest form of altruism, is fueled by self-interest: proving to yourself that you're a decent person, a worthy person, however briefly, before the lights go out for good. 

						So you try to intuit those NPCs' intentions and motivations by looking at their pixelated black-and-white portraits. Surely there must be something there that would clue you into their personalities, their internal workings, what makes them tick. 

						Or perhaps people are fundamentally unknowable. 
					#I am suspicious of these, but I go for them anyway. 
						*set brave %+small_change
						*set chaotic %+small_change 
						Despite your suspicions, you 
						*goto knight_continue 
			#Dig! 
				*set dig true 
				It's a weird one, a cross between [i]Snake[/i], that game where you are a snake burrowing through a screen of soil, getting longer and longer and trying not to eat your tail, and a maze game, where you're trying to find your way out of the labyrinth or towards some kind of prize. 

				Except, in this game, you're not a snake. You can't actually see yourself, as [i]Dig![/i] has a first-person point of view, but you have the sense that, as the game proceeds, you get larger and larger, because everything around you becomes progressively smaller. The terrain keeps changing: from something gritty and thick, when you are presumably underground and digging your way through soil, to something more sturdy like cement, and eventually to something dark and airy, punctuated with bright points that could be stars, as if you've dug your way through the heart of the earth, pierced through the concrete city-crust of the planet, and then burrowed right into the sky. And then you kept going, digging your very own hole through the eye of the universe. 
				*fake_choice
					#It's kinda meditative. 
						You can sink hours into that game. You kinda have—you've been playing it for at least a year now. 
					#It's kinda sad. 
						*set NPC true 
						There's a special kind of loneliness in [i]Dig![/i] The character in this game—whoever they are—has to make their way through the entire game on their own. They do meet NPCs that speak to them, but the character never answers, and it's never clear whether the NPCs could hear them even if the player spoke. As if they existed on a different plane. 

						And that's sort of the heart of the game, isn't it? The character—and let's face it, that's you—keeps digging and digging, laboring and breaking themself against all manner of matter, keeps trying. But they never arrive anywhere. No one ever meets them. 
					#It's a great way to kill time. 
						There's something soothing about the repetitiveness of it, and the game comes with a thunk-thunk kind of digging sound effect that is just so satisfying to listen to. And you have, for hours on end. 

						Except not when you're at the store. Here, you play with the volume all the way down to zero. 

				You never find out whether you're trying to escape the town—is it even a town, or have you projected that onto the cosmology of the game?—or whether you're trying to find an item hidden somewhere within the game's seemingly ever-expanding world. The poetry—or irony, however you want to look at it—of this does not escape you: here's a player who keeps growing, and the world grows around ${em}, expanding to accommodate ${em}. It's either terrifying or beautiful. Or both. 

				You also never find out what causes your expansion, whether it's time or something else, like consuming what you excavate, absorbing your surroundings. 

				Or, perhaps, you grow precisely because the world keeps getting larger and you're simply trying to keep up. 

				@{NPC The NPCs you come across|Along your journey of digging, you come across various NPCs who} give you tips on where you need to go, without ever being clear about what their motivations are for helping you—if they are indeed helping you. Sometimes you wonder if they're trying to mislead or trick you for some kind of personal gain, and if, therefore, the question the game poses is whether you can actually trust them, and which ones you should. 

				You look at their portraits then. Is there something in their faces that should tip you off? A quirk of their physiognomy that betrays what lies beneath, what moves a person? 

				Or, perhaps, people are fundamentally unknowable. 
			#Kafka's Builder. 
				*set kafka true
				This is a cross between Tetris and a builder simulator. You get a random stream of colorful building blocks that you're meant to use to make structures of specific shapes and specifications within a certain amount of time. If you make a mistake, the buildings collapse and you have to start over. If you run out of time, the buildings collapse and you have to start over. And that's the thing that players either love or hate about this game: if you win, if you do everything perfectly and beat the clock? The buildings collapse. You get to start over.

				NPCs pop up with dialogue boxes at regular intervals, shouting "KEEP GOING!" or "USE MORE RED ONES!" or "MAKE SOMETHING POINTY!" though the purpose of what you're making is never quite clear, just as it's never clear to you whether these exclamatory sentences are meant to sound motivational or domineering. Are these people cute little helpers spurring you on, or are they your masters commanding you to work faster/better/harder? You really don't know. You keep building, though. 

				And perhaps that's the point. 

				Why do you keep building? 
				*page_break
				*check_achievements ending 
				Sometimes, the NPCs point out that some of the bricks you've laid are wrong, or praise you for practically identical structures. You grow to learn that praise and criticism are arbitrary and bear no necessary connection or correlation to the actual quality of your work. They are only ever tied to the motivations of your employers. You realize it's a metaphor of some kind: capitalism and the pointlessness of labor, the normalization of exploitation, the Sisyphean trap modern humanity calls a life. Or something.

				In any case, it's also made you think about the way these NPCs are presented through their portraits. Are these meant to offer an indication of their motivations? Can you tell if someone means well, if someone is an ally or an adversary, a comrade or an oppressor, by looking at their face? That's some Nazi shit, isn't it? That can't be right. And yet, something must be communicable through a face's features. You must be able to glean a person's intentions from their physicality, even if you can't see them. Otherwise, how can you connect with anyone? How can you know anyone at all?  
			*if choice_achieved_ending
				#Choice of the Haunted. 
					*set cog_haunted true
					It's a text-based game about a haunted game. In it, the player character and ${eir} group of friends (two boys, two girls, though one of them, you suspect, is actually also a boy) play a game that gives them increasingly suspect challenges. Eventually, the game overflows. It escapes the confines of its own physicality and haunts the players' reality. 

					Perhaps if you had played the game when you were younger, it would make you wonder. Why do these people keep playing? It's obvious that the game is sinister, that nothing good can come of playing it. Why don't they just leave? 

					You know better now. 
	#Read. 
		*set hobby 3
		*set composure %+hi_change
		The truth is, you've been reading for as long as you remember, long before you went to school. You taught yourself to read by peeking over your mother's elbow when she leafed through magazines and asking what the captions said under those photographs of unhappy women and shiny men. Your parents haven't done much for you, have rarely even noticed you, but they did do this for you: they saw your love for words, and they made sure you had things to read. 

		Neither of them was much of a reader, so they opted for quantity rather than quality, and got you books wherever they could find them: yard sales, charity shops, any friend or relative with the tiniest bit of interest in getting you presents. And you still remember that time when your father, a handyman by necessity rather than by training or trade, came home with a cardboard box full of books. He had done a job for some lady who had even less money than your family did, and your father had agreed to be paid in kind. The box was full of novels, most of them for readers older than you, but you didn't mind. There, you found your first Tolkien and Verne, your first Le Guin, your first Delany, your first King. You read every last page in that box, read it again, then kept going. 

		But tonight, you're reading this: 
		*choice 
			#[i]The Picture of Dorian Gray[/i], by Oscar Wilde. 
				*set dorian true 
				*check_achievements ending painter 
				Dorian Gray is beautiful but understands that his beauty will one day fade. He sells his soul to live a life of hedonism that will leave him unmarked, forever young and beautiful. It is only his portrait, his picture, that becomes a record of his sins. 

				You knew what the book was about, of course, long before you started reading it. It's the kind of work one absorbs by osmosis, by simply being part of a 
				*if choice_achieved_ending
					culture, as we all are. (And when I say culture, I mean any culture, on account of anglophone cultural imperialism, etc.) 
				*else
					culture and all its accompanying obsessions. 

				Whatever your beliefs about hedonism, sin, and beauty—if you've already made up your mind about those—the book also made you think of portraits.
				*label portrait_thoughts

				What can a face tell you about the person underneath? Can you intuit someone's inner workings by looking at their features, their eyes, the way they hold their mouth? 

				Or perhaps it's wrong to distinguish between a person and a face in the first place. Perhaps it's wrong to assume there's an "underneath" at all. 
				*if choice_achieved_painter 

					A strange feeling comes over you. 

					As if you know what it's like to paint a portrait of yourself and fail to find your face in it. 

					You've had such thoughts before, haven't you?
					*goto painter_continue
			#[i]The Masterpiece[/i], by Émile Zola. 
				*set zola true
				In it, an artist whose talent the world fails to appreciate gradually becomes fixated on a single painting, a spectacular view of the city of Paris. For this, he constructs an enormous canvas that he hopes will be able to contain his masterpiece. However, this obsession slowly consumes him. He becomes depressed, perhaps mad. 

				You haven't finished it yet, but you doubt it will end well for the artist. 

				The edition of the book you have shows the artist on the cover, hunched in front of a canvas, his palette in hand. But, strangely, the painting he is working on is not the titular masterpiece (or maybe it is?). Not the city of Paris, but a self-portrait. It seems to say: whatever they do, whatever the subject they choose to depict and the pains they go to just so they can get it right, in the end, an artist only ever paints themself. 

				Perhaps that's true, perhaps not. Either way, it's made you think about portraits. 
				*goto portrait_thoughts 
			#[i]Rebecca[/i], by Daphne du Maurier. 
				*set rebecca true
				*if name = "Rebecca"
					You were drawn to it as soon as you saw it in the bookstore. Your name was on it, red on black, in exquisite calligraphy. How could you resist? 

				It's the quintessential Gothic novel: a young, unnamed ingénue marries a wealthy widower and moves into his creepy old house. Eventually, the young wife discovers that her husband's previous wife, the titular Rebecca, died in a sailing accident. So far so haunted. 

				But there is one scene in the novel that has stayed with you, and which you go back and read sometimes, even though you haven't yet gotten to the end. 
				
				At Manderley, the mansion where the novel takes place, there is to be a fancy dress ball. The housekeeper suggests that the master's new bride might take inspiration from one of Manderley's ancestral portraits. So she does. She picks one of a woman in a flouncy white dress and a wide hat and orders an outfit to match the one in the portrait. And then, at the ball, when she appears at the top of the grand staircase wearing that outfit, everyone falls quiet. 
				
				“What is it?” she asks, not knowing what misstep she's made this time. “What have I done?” 

				Later on, she finds out: Rebecca, her predecessor, once wore an identical costume to a similar ball. They looked so alike that everyone thought they'd seen a ghost.

				The other thing that strikes you about the novel is that the woman never gets a name. Only the ghost does. 

				And it makes you wonder. 
				*fake_choice 
					#Are we ourselves, or pictures of ourselves? 
					#How do others perceive us?
						Can we ever be accurately perceived? Accurately represented? Rebecca's portrait, how true to life was it? 
					#Are we doomed to repeat the scripts written for us? 
						Do we simply slot ourselves into predetermined roles, mold ourselves into preexisting notions of what we think we should be? Like the nameless bride, fashioning herself after a picture. 

				And that's the thing about portraits, isn't it? 
				*goto portrait_thoughts

Don't you ever think about this? 
*label painter_continue 
How it's impossible to access anyone else's consciousness, think like they do, see what's in the secret folds of their brains? 

*if hobby = 1
	Perhaps, if you drew them. What can a portrait tell you? Does someone's personality manifest in their face? Their posture? 
*elseif hobby = 2
	When you play a game, are you yourself? When you pretend you are someone else, do you become them? And for those fleeting moments when you do, what happens to you? Where do you go? 
*else 
	Is it ever possible to access someone's internal reality? 

	That's one of the reasons you read, anyway. Isn't it? 
*page_break The Door Chimes Open
*check_achievements ending 
Your thoughts are interrupted by a customer walking in. It's an old lady (she must be like forty or something—really old). You wonder what she's doing out this late. Don't old people all go to bed by 10 p.m.?

@{hobby You put away your sepia paper|You switch off your handheld|You put away your book} and wait for the old lady to slowly make her way through @{hobby this clean, well-lighted place|the store|the store} and pick up 
*if choice_achieved_ending
	black milk, a tub of sand, and some of those long strings of tape people hang on their ceilings to trap ghosts.  
	*page_break Wait, What?
	No, no, it's @{sleepdeprived the sleeplessness|this game—it's getting to you}, isn't it? The old lady puts the items on the counter and it's only normal things, only 
milk, bubblegum, a book of crosswords, and some fly traps@{choice_achieved_ending |, which she deposits on the counter in front of you}. @{(hobby= 3) You half expect her to ask you for a packet of nada. You know, like the old man in that Hemingway story.|}

Sometimes, you look at the objects people select and come up with stories about them. Imagine their lives, their habits, the things that fill their days: the glass of warm, bubblegum-flavored milk on the worn wooden table, the rolled-up crossword used as a weapon against the horde of flies that have taken over her house. 

The woman pays. Goes. You're alone again. 
*fake_choice 
	#Time stands still. 
	#My mind races. 
	#I listen to the quiet buzzing of the lights. 
You steal another glance at the game@{hobby  |—the game! The real game—| }and think over the first task it gave you. It was a bonding exercise. You had to find the first door, and at the door, you had to tell each other a hard truth, something you really believed about your friends—Maria, Joshy, ${Cat}, Tommy—but that you would never have dared say to their face had the game not insisted on it. It's innocent, you reassured each other. It's only a game. Innocent, if slightly cruel. 

You'll never repeat what you told each of them. Just as you will never forget what they said about you: 
*choice 
	#"Your bravery lacks sense. It will get you killed."
		*set chaotic %+mid_change
		*if brave < stat_mid_pass
			It struck you as strange that they talked about you being brave. That's not how you see yourself. But you didn't have to agree with them, anyway. That wasn't the point of this. 
		*else 
			You didn't agree with them, of course, but that wasn't the point of the exercise anyway. 
		*set brave %+mid_change

		Besides, deep down, don't you think they're right? Not about the being killed part. They can't know that, can't predict the future. The chaotic part: you barely think before you act. You just throw yourself into whatever danger crosses your path, as if you're compelled. As if you have some kind of death wish. 

		But you don't. Right? 
	#"You may think you're brave, but really you're just arrogant."
		*if brave < stat_mid_pass
			How weird it seemed to you that they think you consider yourself brave. Because that's not how you see yourself at all. 

			Are they right? 

			But anyway. 
		*set self_centered %+mid_change 
		*set brave %+mid_change
		You didn't say anything to defend yourself. But why would you? What's the point of humility, anyway, and what's bravery without self-belief? You have to be a little arrogant to throw yourself in the way of danger, right? If you don't believe you're the shit, the most likely outcome is you'll get squashed. Arrogance? Pfft. It's survival.  
	#"You hide your fear behind your love for discipline."
		*if brave > stat_mid_pass
			Cowardice? Is that how they see you? You always thought of yourself as brave. 

			But maybe your friends are right. 

			You didn't respond. 
		*else 
			You didn't agree with them, of course. 
		*set chaotic %-mid_change
		*set brave %-mid_change
		You didn't say anything. You couldn't have: there was a knot in your throat, but of course you didn't let them know that, did you? You told yourself these were the rules of the game, no talking-back allowed. Which only goes to prove their point. How right they are about you, the disciplined, orderly coward. 
	#"You think you're so wild and free, but really you're just selfish."
		*if chaotic < stat_mid_pass
			Wild and free? Is that you? Are they right? 

		*set chaotic %+mid_change 
		*set self_centered %+mid_change 
		You didn't contradict them. You would never admit it to them. But are they right? Perhaps, in your disregard for rules, you have sometimes been oblivious to other people's feelings and needs. 

		That kinda makes you self-centered, doesn't it?
	#"You behave like a martyr, but really you're just scared to live."
		*if self_centered > stat_mid_pass
			You never thought of yourself as selfless. 

			But perhaps your friends are right. 
		*else 
			You didn't disagree. You didn't say anything.
		*set self_centered %-mid_change
		*set brave %-mid_change

		All your life you've sacrificed yourself for others. Other people's needs always came first. You told yourself that's noble, that's a life well-lived, a life in service of others. But are your friends right? Is that also cowardly? After all, if you never try to do anything, be anything, leave your comfort zone, there's very little chance of being disappointed or hurt. 

		There's also very little chance of actually living. 
	#"You're so self-absorbed it actually makes you sloppy."
		*if self_centered < stat_mid_pass
			Self-absorbed? 

			You never thought of yourself that way. But perhaps your friends are right. 
		*else 
			You didn't object. But it did hurt. 

			Are they right? 
		*set self_centered %+mid_change 
		*set chaotic %+mid_change 

		You always thought self-love was a good thing. You have to take care of yourself first before you can take care of others, isn't that right? But now your friends are telling you you've taken this to such an extreme that it makes you inconsistent, careless. Dangerous. 

Anyway. 

Perhaps this job is not good for you. Too much time to spend alone with your thoughts. But it's important to keep it. 
*choice 
	#I need money to escape this town. 
		*set escapism 2
		You're not entirely sure what it is you want to escape to. But you sure as hell know what you're escaping from. 
		*page_break Let's Not Go There
	#I need money to support myself when I get into college. 
		*set ambition 2
		You imagine it, sometimes. Studying something you actually enjoy, something that matters. To the world and to you. 

		One day. 
		*page_break 
	#I need to make a living. Support a family, one day. 
		*set romance 2
		Can you imagine? Being someone responsible for the well-being of people you love, people you chose. And succeeding at it. 

		Maybe. One day. 
		*page_break 
Finally your shift is over, and you go home. 

Darkness greets you, not even a lonely lamp or a night-light left on to welcome you. Your parents are asleep—Dad in the bedroom, Mom on the couch. You pass her on your way to your room, and she doesn't even stir. 

The moment you go through your bedroom door, you feel the exhaustion. 
*if not (Choice_nightmode)
	You turn on your bedside lamp. 
*else 
	You don't turn on the light. 

It's an hour till dawn, which means an hour before you have to leave for school. You lie on your bed @{sleepdeprived but know you won't sleep. You'll simply|and hope for sleep that eludes you. You} listen to the sounds of the house, that house you've always thought was haunted: floors creaking under nobody's footsteps, pipes moaning in the walls. On the ceiling, a large treelike shape spreads its branches, dendrites of mold reaching, searching. 
*if not (choice_nightmode)
	*page_break
	You wonder: if you turned off the light, would it look different?

	Turn off the light. 
	*page_break
	*if choice_nightmode
		*page_break
		*achieve lights 
		It does. 

		With the lights off, it looks more like a sea creature. Something ancient and tentative. 

		Something that wants to meet you. 
	*else
		*page_break
		Or don't. Suit yourself. It's your choice. 

		Maybe next time you'll choose differently. 

		Either way, sleep evades you. 
*page_break 
If someone asked you how you became the designated keeper of the game, you couldn't quite tell them. But you did, and here you are. 

You think of it now, its strange material, its inert screen, the mysterious messages. You wonder when the next instructions will appear. None of you remember who first found the game. Of course it piqued your interest; this is the early 1990s, after all, and, in this town, most of the time it still feels like the 1980s. Strange things happen. Your friends were intrigued; you were all intrigued. What does it matter if no one remembers exactly how you came upon it, or if the story changes a little bit, every time you tell it? 
*comment If you're wondering about the chronology here, Player, considering that [i]Xena[/i] premiered in 1995 and that people didn't say "idk" back in the nineties, you're right. This is fake, nostalgic nineties. The imaginary nineties of my youth. Memory is the worst historian. 

Was it found in the woods behind the old monastery? Did someone hand it to one of you on a cold night not long ago, on a street corner downtown? Did you try to retrace your steps night after night, but were never able to find that corner again, as if those streets had vanished, or had never existed at all? And did the student who accepted it have to pay for it somehow? What did they pay with? What was the price? 

None of that concerns you now. 

All that matters is that you keep playing, and that you keep, more or less, winning. 
*check_achievements ending eldritch 
*if choice_achieved_ending
	You've heard it said that hell is a haunted house. Hell has levels too, doesn't it? You've heard that, too. 

	So you advance through the levels—open the temporary doors, enter the impossible rooms, greet the looping, 8-bit ghosts. Ignore the chiptune music. 
*page_break 
*check_achievements ending eldritch 
In the morning, you walk to school. The building sits in a sort of natural basin, at the bottom of three different hills, so on your way there you get a view of it from above. 

From this vantage point, watching the students make their way in, it feels as if you're all pooling towards it, as if it's sucking you in, pulling you to it. 
*if choice_achieved_eldritch 
	Briefly, you imagine the school as a creature, nestled in its basin, invisible tentacles reaching out to pull you in, draw you into its open maw. 
*if choice_achieved_ending 

	You do a double take, with a feeling like something falling through your chest, or your brain bisecting. Déjà vu. Like you've had this exact thought before. 

	You've been here before. You know all this already. 

	Of course you know all this. Of course you've been here before. This is where you go to school. 

	(Though we both know this is not what I meant.)
*else
	It's a gray concrete building that always felt to you as if it pretends to have more windows than it actually does. Its corridors feel too narrow for the number of students walking them. Its structure makes everyone rush, elbow one another to keep moving, keep moving, keep moving, as if the school itself is herding you along, circulating you, distributing you from its long, long veins to its vital organs. 
*page_break 
In the first period, Ms. Harper, your @{hobby art|computer science|literature} teacher, calls on you. She asks you a question about @{hobby linear perspective in Renaissance art|exit control loops|the fragmentation of self and narrative in early modernist literature}. 
*choice
	#I studied hard, like I always do, but my brain is hazy. 
		*set chaotic %-mid_change
		It's not your fault. Maybe you're just tired. You always apply yourself. You do your best, and that's the most anyone can do. 
	#I never study. What's the point?
		*set chaotic %+mid_change
		You figure that if there's anything you need to know to get ahead in life, life itself is going to teach it to you sooner or later, one way or another. Usually one hard way or another. What could school—this artificial, carefully controlled environment—possibly give you that would prepare you for the jungle that lies beyond its gates? 
	#I don't need to study. I'm talented, and that's enough.
		*set self_centered %+mid_change
		Maybe a tad arrogant, too. But who cares? Only the talented can afford that. 
		
		Besides, there's nothing a book can teach you that you can't get from just believing in yourself. You already have all the internal resources you need to get ahead. 
	#Regardless of whether I've studied, I hate speaking in front of people. 
		*set self_centered %-mid_change
		Even if you know the answers, @{(chaotic >= stat_mid_pass) which, let's face it, is not often|which is most of the time}, you just become tongue-tied as soon as you are in the spotlight. This has led some people to think you're stupid, or that you don't apply yourself. But you know neither of those things is true. You're just too distracted by your racing heart and your sweaty palms to focus on forming words that make sense. 

You stammer through your answers. Ms. Harper lets you finish and then, disappointment plain on her face, puts you out of your misery by calling on someone else. 

One by one, you glance at your friends in the classroom. There's Joshy, the angsty teenager who sings and plays the guitar and hides his sadness behind the most luminous smile; ${Cat}, who is beautiful and rebellious and @{(Cat = "Cat") who trusted you enough to come out to you as trans one night not long ago, under the great horse statue at the seafront, where ${ce} likes to skate|likes to skate under the great horse statue at the seafront} with all the tough boys; Maria, who sits next to you in class, has a [i]Xena: Warrior Princess[/i] obsession and a desperate crush on Gabrielle; and Tommy, who is small and often seems helpless, but who is also the best student in the class (and the only one who has a semblance of a normal family life). You are all almost eighteen years old, except Tommy, who is a year younger. Tommy catches your eye and smiles encouragingly. Maria looks away to avoid embarrassing you. Joshy winks, and ${Cat} rolls ${ceir} eyes at Ms. Harper. 

They're good friends. 
*check_achievements ending 
*if choice_achieved_ending

	But look. Obviously, these people are not Maria and Tommy and ${Cat} and Joshy. They are meant to stand in for whoever your friends were when you were growing up. I can't actually make you care about any of them. You have to do that on your own. 

@{(brave > stat_mid_pass) Lips pressed together|Cheeks flushed}, you suffer through the rest of the class. ${Cat} breaks a piece off ${ceir} eraser and throws it at you, hoping to make you laugh. Almost succeeds. Even though this is your favorite subject, and Ms. Harper your favorite teacher, you can't bring yourself to concentrate on anything she says. 

Maria, ever caring and kind-hearted, bumps you with her shoulder. "You okay?" she mouths silently.

You nod. But your mind is on the game, your hands itching to reach into your backpack and check it for new instructions.
*page_break 
When the bell finally rings, you let out a long breath. But as you're on your way out, Ms. Harper asks you to stay behind for a minute. 

You rub your sweaty palms on your trousers and approach her. 

"You need to apply yourself, ${name}," she says. Not unkindly. "You're a smart kid. One of the @{hobby most creative|smartest|most perceptive} students I've ever had the chance to teach, in fact. Please, don't let that go to waste."
*fake_choice
	#I mistrust compliments.
		*set brave %-mid_change
		You don't know if it's because praise was so rare in your family when you were growing up, or because, on the rare occasions when your mother or father did praise you, it always came at a cost or with a bunch of strings attached. Being praised meant you'd given up something you didn't want to give, or you'd taken something you didn't want to take. 

		"If you say so, Ms. Harper."

		The teacher holds your gaze a moment too long. Then, she decides you've had enough. You can't tell if it's because she has resolved to pick up this particular battle another day, or if she's finally accepted you're a lost cause. 

		"Okay, ${name}. I'll see you tomorrow, yeah?"
		
		"Of course." Is this over yet? 
	#I don't know what to say. My cheeks burn. 
		*set self_centered %-mid_change
		You never particularly @{like_attention tried to be|liked being} the center of attention. @{(self_centered > stat_mid_pass) It just kinda…happened. But you didn't seek it. |}Sometimes you wonder where that attitude comes from. Were you shamed by your parents or some teacher early in life and you just don't remember? Were you ever punished or bullied for speaking your mind? Were you taught you needed to be perfect all the time, to always get it right, and if you weren't or you didn't, then it was better not to open your mouth at all? 

		But maybe it isn't right to look to the past for answers. It's kinda deterministic, isn't it? As if people are always perfectly coherent narratives, as if you can solve their inherent riddles by simply finding the right sequence of events to explain them. 

		Perhaps you're just naturally that way. 

		You shift awkwardly where you stand. 
	#I smile, bolstered. 
		*set self_centered %+mid_change
		It's good when people believe in you. And why wouldn't they? Deep down, you do believe you're great. Like you really, actually believe it. 
		*if brave >= stat_mid_pass
			But it's good to have that external validation. Otherwise it's just something you believe; it might not actually be true. 
		*else 
			Except you can't really say that out loud. Because that would be dangerous, wouldn't it? It's a fine balance, wanting to be the center of attention without actually attracting any trouble. 

		"Thank you," you say. And you mean it. 
	#I bravely apologize for fumbling earlier. 
		*set brave %+mid_change
		"I'm sorry, Ms. Harper," you say. "I didn't want to disappoint you. I'll do better next time."

		Ms. Harper smiles, though there is a hint of something reserved in her expression, as if she mistrusts how readily you owned your mistakes. "I'm sure you will," she says. 

		You take that as being dismissed, but as you turn to go, Ms. Harper speaks again. "I have faith in you, ${name}," she says. "Please, remember that."

		It's meant to be a compliment, or a statement of support. So why does it sound so ominous?

Ms. Harper's eyes take on a slightly glassy quality. "It's so easy to throw away your life, you know," she says. "Easier than you think." She pauses. "And you have a test coming up next week. Don't forget." It's plain that there's more she chooses not to say. 

You let it go. 

After class, you notice the game has lit up with new instructions. 

You let everyone know you're on.
*page_break 
You meet up by the gym. You exchange a few glances, and then, without ceremony, you open the door—the one in front of which you once shared your cruelties. 

Behind the door is a room full of sand. Or no, not a room. A space. 

You walk in slowly and it's like entering another world. Strange light.  If you look closely, at the right angle, with your head tilted slightly and your eyes half-closed, you might see things differently. 
*if choice_nightmode 
	Strange formations, person-shaped, where others had perhaps stood before you. 
The game is everywhere. You can't see where it ends. 

The door clicks shut behind you. You try the handle, but it won't budge. You're locked in. 

To play this game, according to the instructions, first you have to decide who will lose. The decision must be final and uncontested.

"But it can't be just that," Joshy says. "What kind of game would that be? That's no game at all."

"Maybe it's a trick," ${Cat} says. "Maybe the game wants us to go against its instructions. Try to beat it."

"Or maybe it just wants us to do what it said?" Tommy interjects. "The instructions were quite clear."

Maria is the only one who remains silent. She studies the space, a fearful look on her face. 
*choice 
	#I hate to see Maria scared. 
		*set Maria %+mid_change 
		What is it about her? Something in the way her feelings register on her face, despite how little she says. Makes you want to take care of her. 
	#I like how rebellious ${Cat} is. 
		*set catrina %+mid_change
		$!{ce} always thinks unconventionally. Out of the box. 
	#I like how sensible Tommy always is. 
		*set tommy %+mid_change 
		Because what he says does make sense, 
		*if brave >= stat_mid_pass
			even if it comes across as cowardly. 

			Still, there's no harm trying to do things differently.  
		*else 
			doesn't it? 

			But the majority has spoken.  
	#I like Joshy's skepticism. 
		*set joshy %+mid_change 
		He never goes along with authority. Always tries to do things his own way. Perhaps you can take a page from his book.  

Finally, you speak. "There must be another way," you say. 

You wander in the space and make shapes in the sand for a while. A cross. A circle. A snake eating its own tail. 

Perhaps you should try doing the thing you're best at? @{(hobby = 2) Because you've found this sometimes works in games.|Surely, this is the kind of situation that calls for good use of one's skills. And you know what yours are.}
*choice 
	#I'm smart and perceptive.  
		*set insight %+hi_change
		You study the space and notice there are circles in the sand that you didn't trace yourselves. They were already there when you walked in. That must mean something, right?

		*if chaotic >= stat_mid_pass
			Not that you have any faith that things necessarily have meaning. 
		*else 
			Things exist for a reason. Everything has meaning. Especially in a game, randomness is the enemy of good gameplay. 

		You point the shapes out to the rest of the group. 

		"What do you think they are?" Joshy asks. 

		"Perhaps there were others here before us," you say. Not that this helps your situation. 

		"Let's just choose someone," Tommy says. 

		Reluctantly, you agree.
	#I'm athletic. 
		*set athletics %+hi_change
		You warm up a little, and then you run as far as you can. You're @{(self_centered >= stat_mid_pass) pretty proud of your stamina. Surely, if you keep going, eventually you'll reach|reasonably sure you have enough stamina to make it to} the end of this room. It is located somewhere within the school, after all, isn't it? It can't go on forever. 

		And yet. You keep going until your legs turn to rubber and your breath threatens to burn your lungs down to ashes, but the end of the room is nowhere in sight. The light remains unchanged. 

		When you drag yourself back near the door and reunite with your party, you can hardly speak. You shake your head. "It doesn't end," you say. 

		"That's impossible," Maria says. 

		You shrug. "Maybe." 

		"And it doesn't quite help us."

		"No," Joshy says. "It doesn't." He pauses. "Let's just follow the instructions," he says then. 

		Reluctantly, you all agree. 
	#I am mature and level-headed. 
		People tend to turn to you when things get hard: to trust you, find a leader in you, @{(self_centered < stat_mid_pass) despite the fact that you're rather quiet|which of course comes naturally to you}. 

		And that's what happens this time as well. You're the closest thing there is to an actual adult around here, so you organize them, put a speaking order in place, and let them brainstorm ways to get out of here. Each of your friends makes a proposition: running to the end of the space to see if there is a door on the other side, digging in the sand to see if there are any hidden clues there, yelling really loudly so someone comes and lets you out. 

		You try each of these methods, and each one fails. 

		In the end, you decide that you should just do as the game instructed. So you allocate each of your party members a few minutes to decide who they're going to pick. If feelings get heightened, you're prepared to intervene and be the voice of reason, remind everyone you're friends. It's only a game. You can get through this if you just remain calm. 
		*set composure %+hi_change

The game will only let you out if you all agree on a decision. Once you have decided, you have to wound the loser, spill a few drops of their blood in the sand. Just a tiny bit. The game needs its sacrifices. 
*check_achievements second_ending 
*if choice_achieved_second_ending
	
	So who are you going to pick? 
	*goto pick 
Before you make a decision, you think about each of your friends. 
*label friend_loop 
*choice 
	*disable_reuse #Think about Maria. 
		You remember all the times you snuck out on a school night to go to the movies with her. 

		Your town only has one movie theater, and they usually only bring the blockbusters in, but sometimes they'll show something old, like a black-and-white Western subtitled so badly it makes you wonder if any of the words you're hearing actually correspond to what the actors are saying. Maria, for some reason, loves those most of all. 

		Sometimes, instead of watching the film, you watch her. The way her face looks, mesmerized, awash in the silver magic of the screen. 
		*set loop +1 
	*disable_reuse #Think about Tommy. 
		Tommy's favorite pastime is going to the big bookstore downtown. 
		*if hobby = 3 
			You understand why. You often go with him. 
		*else 
			You don't quite get what he loves so much about it, but you still join him sometimes. 

		Together, you sit on the floor of a different section each time you go. Tommy takes down piles of books—sometimes it's fantasy or science fiction, other times it's horror, or comic books, or thrillers, or detective stories, or even sad, magic-tinted fables. Tommy doesn't discriminate. @{(hobby = 3) You leaf through the books, absorb what you can. You don't even have to talk. Just being together among words is enough.|You watch him leaf through the books, and there's something about the pleasure he takes in them that makes the whole experience worth it, even if you're not that into reading yourself.}
		*set loop +1 
	*disable_reuse #Think about ${Cat}. 
		You join ${cem} when ${ce} goes skateboarding, sometimes. @{(athletics > stat_mid_pass) You've tried skating yourself, and you're good at it, even if it's not exactly your thing. Mainly you enjoy watching ${cem} do it.|You never skate yourself, but you watch ${Cat} do it, and it's enough.} There's something about the way ${Cat} skates—the boldness in the way ${ce} moves, the wild joy—in ${ceir} face. It's mesmerizing. As if, for a few short hours, ${ce} is ultimately, completely free. Completely ${cemself}. 
		*set loop +1 
	*disable_reuse #Think about Joshy. 
		He made a recording of himself singing a song he wrote, once. He gave you a tape and didn't say anything, scared that you'd hate it or make fun of him. 

		You listened to that tape on repeat for an entire night. The song itself was simple; basic melody, heartfelt lyrics about the sky and the sea and how lonely and empty they both feel sometimes. But there was something in Joshy's voice that made the recording irresistible to you. An earnestness, an openness. Something hopeful. As if whoever had that voice was simply incapable of being sad. 
		*set loop +1 
*if loop < 4
	*goto friend_loop 

These are your friends. You have good memories with all of them. 

But who are you going to pick?
*label pick 
*choice 
	*selectable_if (maria_pick) #Maria. @{(Maria > stat_mid_pass) Reluctantly.|}
		*set maria %-small_change 
		Maria is fine and everything, but sometimes she can just be so single-minded. And her Xena obsession is getting old real fast. 
		*choice 
			#I'm only making excuses, of course. I feel guilty. 
				Maria doesn't really deserve your vote just because she's, idk, quirky or whatever. 

				But you have to pick someone. 
			#Or maybe I'm just looking for a reaction. 
				How better to get someone to react than picking them to bleed in some weird-ass game, right? Sure. Makes perfect sense. 
			#I could have picked any one of them and it would have hurt the same. 
				*check_achievements ending 
				It's just what the game demands of you.

				After all, if it were an easy decision, the game wouldn't matter as much, right? And you have a sense that what the game really wants is your emotional involvement in every decision you make. 

				*if choice_achieved_ending
					There was a time when you'd have taken a step back at this thought, wondered where it had come from. What the game wants? How ludicrous. How impossible.

					You don't ask such questions anymore. 
				*else 
					Wait. What the game wants? 

					The game doesn't want anything. It can't, can it? It's just a game. Someone designed it. They're just trying to create a high stakes situation—and what better way to do this than pitting a bunch of friends against one another? 
		*goto decision 
	*selectable_if (joshy_pick) #Joshy. @{(Joshy > stat_mid_pass) Reluctantly.|}
		*set joshy %-small_change 
		*set chosen 2 
		Joshy is great of course, he's your friend, but sometimes he just seems too perfect. For someone who's supposed to come from a home as broken as yours, sometimes you get the feeling that he should be just a little bit more, you know, fucked up? Instead, he seems to be using all the tragedy of his life as fuel to be artistic and charming. 
		*choice
			#Maybe I'm just jealous.
				Yeah, maybe. Just jealous.

				You note how much work that little word, "just," is doing in there. 
			#I'm simply giving him more fuel.
				It's practically a service choosing him. 
			#I'm just making excuses because I feel guilty. 
				And that's understandable, isn't it? People gotta do what they gotta do. You know that much. 
		*goto decision 
	*selectable_if (tommy_pick) #Tommy. @{(Tommy > stat_mid_pass) Reluctantly.|}
		*label tommy_thoughts
		Tommy is a great kid, but sometimes he's just such a weakling. It gets on your nerves. @{(brave < stat_mid_pass) Sure, you're not the bravest one of the bunch, but Tommy is just too mousy, even for you.|Sometimes you wish you could grab him by the collar and shake some courage into him.}
		*set tommy %-small_change
		*set chosen 3
		*choice
			#Or maybe I'm just making excuses because I feel guilty.
				*check_achievements ending  
				Guilty for picking the one you consider the weakest. 

				Guilty for picking the only one you could actually hurt. 

				But that's the game, isn't it? 
				*if choice_achieved_ending
					That's what it wants. An emotional response. 

					And perhaps making you feel guilty is the best way to involve you, to make sure you remain engaged. After you draw blood for the sake of the game, it won't be easy to disentangle yourself. 
				*else 
					This is the kind of behavior it's trying to provoke…. 

					No, listen to yourself. You're attributing too much agency to a game, an inanimate object, something that has no thoughts and feelings. You're projecting all that onto the game yourself. You just have to face it and own up to your choices. 
			#And it's not like we're really going to hurt him.
				*check_achievements ending 
				Right? It's just a game.

				*if choice_achieved_ending
					You keep telling yourself that. 
				*else 
					Tommy will be fine. 
			*if (brave < stat_mid_pass)
				#Perhaps I just see too much of myself in him. 
					And that's hard, isn't it? It's not comfortable when people become mirrors of yourself and you don't like what you see. 

					Better smash that mirror and be done. 
			*else 
				#Perhaps this will teach him a lesson. 
					Help him grow or whatever. Man up?

					Ugh. 

					Did you come up with this thought, or did the game put it in your head on purpose? 

					Either way, you've made up your mind now. 
		*goto decision 
	*selectable_if (catrina_pick) #${Cat}. @{(Catrina > stat_mid_pass) Reluctantly.|}
		${Cat} is great and everything, but sometimes you wonder if the tough act is just that, an act. Perhaps this is how you find out. 
		*set catrina %-small_change
		*set chosen 4
		*gosub catrina_thoughts
		*page_break Right
		*goto decision 
	*if (options != 4) 
		#I love them all. Let me think through the options. 
			It's an important decision. You can't make it lightly. 
			*set tommy %+small_change
			*set catrina %+small_change
			*set joshy %+small_change
			*set maria %+small_change
	*selectable_if (self_pick) #I pick myself. Don't want to hurt any of my friends. 
			*set self_pick false
			It's the only real option, isn't it? 

			You say so and start making your case. 

			But Joshy shakes his head. "Nah," he says. "No way. If that's how it goes, we would all pick ourselves, and we'd never make a decision. Everyone has to pick someone else."

			Looks like this won't go your way. 
			*goto pick 
*label friend_options 
*if options = 4 

	There's nothing more to think about. You have to make a choice. 
	*goto pick 
*choice 
	*disable_reuse #Perhaps I should choose Maria.  
		*set options +1 
		Why would you choose her? 
		*choice
			#Because she's my least favorite. 
				*set maria %-mid_change
				You just don't get along with her as well as you do the others, and you get the impression she doesn't need you as much as the others do. She seems content to do her own thing. 
			#Because I think she trusts me enough not to take it the wrong way. 
				*set maria %+mid_change 
				If there's anything that can attest to the strength of a friendship, it's being able to do things that hurt it without breaking it. Maria knows you love her. This won't damage your relationship. You're sure of it. 

				Right? Pretty sure.  
			#Because I don't want to hurt any of the others. 
				*set joshy %+small_change 
				*set tommy %+small_change 
				*set catrina %+small_change 
				*set maria %-mid_change 
				It's as simple as that. You have to pick someone. It might as well be her. 
				*goto decision 
		*choice
			#Okay, I'll choose Maria.
				*goto decision 
			#No, not Maria. I know who I'll choose. 
				It's obvious now that you think about it. 

				You know who to pick. 
				*set maria_pick false 
				*goto pick 
			*if (options < 4) 
				#Let me think some more. 
					It's not an easy decision.  
					*goto friend_options
	*disable_reuse #I think maybe Joshy. 
		*set options +1 
		Okay. Let's think this through. 

		Why would you choose Joshy? 
		*choice 
			#Because I'm jealous of him. 
				*set Joshy %-mid_change 
				He's just so confident it's unfair. He comes from a home as broken as yours, and yet he doesn't seem broken at all: he seems stronger for it. Charismatic. As if he's taking the same bad stuff you have to endure and turning it into fuel for creativity and, just, idk. Coolness. 

				That's a good enough reason to pick him.
			#Because I believe in him. He can take it. 
				*set Joshy %+mid_change 
				Of all your friends, Joshy seems the most together. If anyone would be fine with being chosen in this situation, it's him. 
			#Because I don't want to hurt any of the others. 
				*set maria %+small_change 
				*set tommy %+small_change 
				*set catrina %+small_change 
				*set joshy %-mid_change 
				*set chosen 2
				It's as simple as that. You have to make a decision, and you might as well pick Joshy. There's nothing more to it. Is there? 
				*goto decision 
		
		So? Have you made up your mind? 
		*choice
			#Okay, I'll choose Joshy.  
				*set chosen 2
				*goto decision 
			#No, not Joshy. I know who I'll choose. 
				Perhaps you're going about this wrong. 

				You have a better idea.  
				*set joshy_pick false 
				*goto pick 
			*if options < 4 
				#Let me think some more. 
					Sure. It's not a decision to be made lightly. That's what makes the game interesting.  
					*goto friend_options
	*disable_reuse #I wonder if I should choose Tommy.  
		*set options +1 
		You make a mental list of all the reasons you might want to pick him. 
		*choice 
			#He's so weak. It gets on my nerves. 
				*goto tommy_thoughts  
			#He's smart enough to understand my decision. 
				*set tommy %+mid_change
				You truly believe he won't take it the wrong way. That's just Tommy, isn't it? Always accommodating, always pliable. 

				Sometimes it seems like you can do whatever you like at his expense, and he'll thank you for it. 
			#I just don't want to hurt any of the others. 
				*set maria %+small_change 
				*set joshy %+small_change 
				*set catrina %+small_change 
				*set tommy %-mid_change 
				*set chosen 3
				It's as simple as that.

				(Though, when you think about it, is there anything simple about that?)
				*goto decision 
		*choice
			#Okay, I'll choose Tommy. 
				*set chosen 3
				*goto decision 
			#No, not Tommy. I know who I'll choose. 
				You have a better idea.  
				*set tommy_pick false 
				*goto pick 
			*if options < 4 
				#Let me think some more. 
					Yes. Let's think. Think think think.  
					*goto friend_options
	*disable_reuse #Okay. Let's consider ${Cat}. 
		*set options +1 
		Why would you pick ${cem}? 
		*choice 
			#Because I admire ${ceir} resilience. $!{ce}'s tough.  
				*set catrina %+mid_change 
				Or at least that's what you think. Perhaps it's all an act: a tough exterior protecting the softest of cores. 
				*gosub catrina_thoughts  
			#Because ${ce}'s so abrasive.
				*set catrina %-mid_change
				$!{ce} rubs you the wrong way sometimes. $!{ce} acts so tough that ${ce} bulldozes over other people and doesn't even notice. Perhaps ${ce} should see what that feels like. 
			#Because I'd rather not hurt any of the others. 
				*set maria %+small_change 
				*set tommy %+small_change 
				*set joshy %+small_change 
				*set catrina %-mid_change 
				*set chosen 4
				It's as simple as that.
				*goto decision 
		*choice
			#Okay, I'll choose ${Cat}. 
				*set chosen 4
				*goto decision 
			#No, not ${Cat}. I know who I'll choose. 
				You have a better idea. 
				*set catrina_pick false 
				*goto pick 
			*if options < 4 
				#Let me think some more. 
					Of course. This is not a decision you want to make lightly.  
					*goto friend_options
*label decision

Before each one of you casts your vote, you agree that the group must go with the majority. You figure it's the only way to reach a decision. Even the person with the most votes must agree. 

"Are we all on the same page?" Joshy asks. 

You all nod. 

"Okay then, let's go," Joshy says.
*page_break You Go First

*if chosen = 1 
	"I vote for Maria," you say. You look her in the eyes and add: "I'm sorry."

	Maria gives you a small smile and shrugs, but you can see in her face that she's a little hurt. "It's all right," she says, while her eyes say something else entirely. "Don't worry about it."
*elseif chosen = 2
	"I vote for Joshy," you say. "Sorry, man," you add, looking him in the eyes. 

	And Joshy, of course, instead of being mad, beams at you, as if you just paid him a compliment (and maybe you did?). "Cool," he says. "Thanks."
*elseif chosen = 3
	"I vote for Tommy," you say. You say it as softly as you can, but Tommy still acts as if he's been slapped. He takes a step back. He looks away, but you can see his eyes are misting up. 

	"Okay," he says. His voice is small and frightened. 
*else
	"I vote for ${Cat}," you say. You avoid ${ceir} eyes as you say it, and for good reason.

	${Cat} takes a step back and acts as if you just punched ${cem} in the chest. 

	"Well fuck you, man!" @{(e != "he") ($!{ce} calls everyone that.)|${ce} shouts.} "I vote for you, then." $!{ce} crosses ${ceir} arms across ${ceir} torso and looks like ${ce}'s trying very hard not to pout. 

Now it's time for the rest of your friends to make their decisions. 

*if brave >= stat_hi_pass
	Tommy votes for you. He avoids looking you in the eye as he says it. Timid as always. 

	Joshy and Maria vote for Tommy. 
	*set tommy %-small_change 
	*if chosen = 4 
		${Cat} votes for you, but you already knew that. 

		That means you and Tommy tie. 

		And of course you wouldn't let little Tommy bleed in your place, would you?

		"I volunteer," you say. "I'm it." 
		*if self_pick
			And before Joshy has a chance to protest again, you raise your hand to stop him. "It's what I wanted from the start, after all."

		Everyone shifts uncomfortably, but nobody argues. 

		Tommy looks away. You both know he's scared. "Thank you, ${name}," he says. His voice is so thin and small you can hardly hear it. 
		*set bled 5 
	*else 
		*if chosen = 3 
			That means Tommy is it, no matter how ${Cat} votes. But  
		*else 
			That means ${Cat}'s choice might produce a tie. But in the end  
		${ce} votes for Tommy, too. "Sorry, man," ${ce} says. 
		*set bled 3
	*page_break 
*elseif self_centered >= stat_hi_pass
	Tommy votes for ${Cat}. Joshy votes for you, looking at you square in the face as he says it. And Maria votes for ${Cat}, too. 
	*set joshy %-small_change 
	*if chosen = 4

		That makes three votes for ${Cat} and two for you. 
	*else 
		${Cat} votes for 
		*if chosen = 2
			Tommy. 
		*else 
			Joshy. 
		
		But it makes no difference. ${Cat} is it. 
	*set bled 4 
	*page_break 
*elseif chaotic >= stat_hi_pass 
	*if chosen = 4 
		Tommy and Joshy vote for Maria, and Maria votes for Joshy. ${Cat} votes for you, like ${ce} promised. 

		That means Maria is it. 
		*set catrina %-small_change 
		*set bled 1 
	*elseif chosen = 1
		Tommy and Joshy side with you, voting for Maria. ${Cat} votes for Joshy, and Maria votes for you, but it makes no difference. 

		Maria is it. 
		*set maria %-small_change 
		*set bled 1
	*elseif chosen = 2
		Everyone sides with you, voting for Joshy, and Joshy votes for you.

		That settles it, then. Joshy it is. 
		*set joshy %-small_change 
		*set bled 2
	*else 
		Nobody else votes for Tommy. Tommy votes for Maria, ${Cat} and Maria vote for Joshy, and Joshy votes for you.

		That means Joshy is it. 
		*set joshy %-small_change 
		*set bled 2 
	*page_break 
*else 
	*set bled 3
	*if chosen = 4 
		No one votes for you except ${Cat}, because ${ce} promised to, and ${Cat} keeps ${ceir} promises. 

		But everybody else votes for Tommy.
		*set catrina %-small_change 
	*else 
		*if chosen = 3 
			You all vote for Tommy. 

			Nobody votes for you at all. 
		*else 
			Tommy votes the same as you, but everyone else votes for Tommy, so in the end it doesn't make a difference. 

	How does it feel that @{(chosen = 4) no one else|no one} voted for you?  
	*choice 
		#Strange. Like I've been snubbed or something. 
			Does it mean something that none of your friends thought you should be the one to lose? 

			Do they think you're so fragile that you couldn't take it, or something? 

			Are they right? 
		#It feels good. My friends don't want to hurt me. 
			They care about you. Right? That's what it means. And that can only be a good thing. 
		*if brave < stat_mid_pass
			#I am relieved. I don't like blood. 
				It's not like there's going to be a bloodbath or anything, but you don't want it to be your blood. Even if it's just a tiny amount. 
		#It makes no difference to me. It's just a game.
			*set just_a_game true 
			*check_achievements ending 
			*if choice_achieved_ending
				Sometimes I really admire people's capacity for self-deception. 

				No, really. It's a survival strategy, a coping mechanism. Totally get it. 
			*else 
				Yeah! That's the spirit. Just a game. 

*if bled = 1
	"Right," Maria says. "Guess I'm the loser."

	${Cat} reaches out and lightly brushes Maria's arm. "Don't put it like that," ${ce} says. "It's only a game. Everyone had to make a choice."

	Maria pulls away. She seems hurt, but tries to hide it. "I don't care," she says. "It's fine." (It really, really isn't.) "I get it." She pauses and looks around from face to face, lingering briefly over yours. "So how are we actually gonna do this? Like, what are we using?"
*elseif bled = 2 
	"Okay!" Joshy says, beaming, as if he wasn't just stabbed in the back by his friend. (Which he wasn't. Just chosen to bleed a little.) "I guess I'm your lamb for the day. Let's get this over with." He thrusts his hands together, wrists facing up, as if ready for handcuffs. "Take me away, officers!"

	${Cat} can't help but give a short-lived giggle. "But wait," ${ce} says then, as if just remembering something. "What are we going to use?"
*elseif bled = 3 
	Tommy's face has gone ashen. @{(chosen = 3) Maybe it's the strange light in this space. Yeah. It's totally the light.|He's terrified, you can see that.} His voice trembles when he speaks. 

	"Okay," Tommy says. He swallows, looks around, shifts his weight from one leg to the other. If he's hurt, he tries to put on a brave face. Unsuccessfully. "I'm ready."

	"Wait," Maria says. "What are we going to use?"
*elseif bled = 4 
	"Okay," ${Cat} says, ${ceir} voice a bit too loud. $!{ce}'s clearly pissed, but ${ce}'s not going to show any kind of weakness in front of all of you. You know ${cem} well enough to know that. "I guess I lost." $!{ce} pauses and looks away. 

	No one speaks for a few moments. 

	"Well?" ${Cat} says. "Can we get it over with, please?"

	"But," Tommy stammers, "how are we actually going to do this? Does anybody have a…I don't know. Something sharp?" 
*else 
	So. You're up. 

	All your friends are looking at you now. 

	"Um…" Maria starts, then stops herself, tries again. "Uh, so, I guess. What are we going to use?"

You had almost forgotten about it. The knife. It's in your backpack, next to the game, wrapped in a paper towel. It's the only part of the instructions you hadn't shared with your friends. The game didn't tell you to keep it a secret; that was your decision. That was all you. 

Why didn't you tell them? 
*check_achievements ending 
*choice 
	#I thought it might influence their decision. 
		You hadn't quite thought through how it might influence them. Might have made the decision more urgent, the danger more palpable. Might even have made you dangerous in their minds, perhaps. 
	#An ace up my sleeve, I guess. 
		A secret to be revealed when the time was right, or something. 

		It's kinda sad though, if you think about it. You're supposed to be a team. How exactly is a smuggled knife an ace up your sleeve? What were you planning to do with it? 
	#I was scared. 
		*if brave >= stat_mid_pass
			You would never admit that to anyone, of course. 

			But at least you admit it to yourself. That's something. 

			Can you also acknowledge what exactly it was you were scared of?  

			Was it what you might be asked to do? 

			Or what you might do without even having been asked? 
		*else 
			That's understandable, isn't it? 

			No one would blame you for that. You didn't choose to be the game keeper anyway. You never wanted this. This responsibility, this burden, the weight of that knife in your backpack all day. (Figuratively: the knife itself is actually pretty light.) You never asked for this. 
	*if choice_achieved_ending
		#This is an unfair question, coming from you. 
			Who, me? 
			
			You are the one who's keeping secrets from your so-called friends. Don't go blaming others for your own choices. Not even me. 

But anyway, the fact is you didn't tell them. And now you must. 

"So…" Your voice sounds hoarse, so you cough, try again. "I brought a knife with me." 

${Cat} shoots you a look so cutting it almost makes the knife unnecessary. "What?" 

"It was in the instructions," you say with an air of finality. You retrieve the knife from your backpack quickly, to preempt any more questions. 

Carefully, you unwrap it. 

"Who has to do it?" Joshy asks. 

*if bled = 1 
	"The instructions didn't say." You look at Maria. "Do you want to do it yourself?" you ask her, and she nods. 

	She takes the knife without a word. Quickly, she pricks her index finger and lets a little blood drip onto the sand. 

	Her eyes look distant, as if she's retreated somewhere far away. 

	"That should do it," you say, though what do you know? You don't know. You only hope. 

	Gently, you take back the knife. 
*elseif bled = 2
	"It didn't say." You pause. "Maybe you can do it yourself?"

	Joshy shrugs. "Sure," he says. He takes the knife from you. He grits his teeth and punctures his index finger, lets a few drops trickle to the ground. "Think that's enough?"

	"I don't know," you say, but you take back the knife anyway. 
*elseif bled = 3
	You hold out the knife to Tommy, hoping he will take it. "I thought maybe whoever we chose could do it themselves." 

	But Tommy shakes his head. "No, please," he says. "You have to do it. I can't."

	You grit your teeth and nod. @{(brave < stat_mid_pass) You hate this.|This is fine. Right? It's only a few drops. Hopefully.} 

	Tommy holds out his hand for you, and you prick his index finger with the tip of the knife. 

	You all watch the blood drip onto the sand. One, two, three drops. 
*elseif bled = 4 
	"The instructions didn't say anything about that." 

	You all look at each other.

	"Oh, for fuck's sake, give me that," ${Cat} says and grabs the knife. Quickly, ${ce} cuts ${ceir} index finger and lets the blood drip onto the sand. "There," ${ce} says, giving you back the knife after ${ce} wipes it on the leg of ${ceir} jeans. "Happy?"
*else 
	"I'll do it myself," you say. 

	You prick your index finger with the tip of the knife. It's just a tiny nick. Doesn't even hurt. 

	You all watch as a few drops of your blood trickle onto the sand. Then you bring your finger to your mouth. It tastes metallic, and is colder than you would have expected. 

It only takes a few moments, but the shift is palpable as soon as it happens: the door opens with a gasp. The ambience in the room (room, space, world, whatever) changes. The light wanes, and the air—that stilted, suffocating, motionless air—starts circulating again. 

The game has had its blood. You are free to go. 
*page_break 
*set level_1_stats true 
Outside, everything looks the same as before, as if nothing has happened. Students linger in the schoolyard, oblivious to the game, its demands, your decisions, and your anticipation. 

You close the door behind you. None of your friends speaks, and you don't look at each other. Only ${Cat} glances at you furtively, perhaps hoping that you don't notice. 

Slowly, together, you climb the hill that leads away from the school, and then you each go your separate ways. 

As you sense the distance between you grow, the game blips with new instructions. 

You take it out and glance at the screen with your breath held. 

Tomorrow, then. At noon.
*finish 
*label catrina_thoughts
*choice 
	#It's basically a test. 
		A test for ${Cat}, right? 

		Not for you. Not for your friendship. 
	#I'm sure ${Cat} will be fine. 
		It's not like you're going to hurt ${cem}. Not really. 

		Maybe it will be good for you—all of you. 
	#And if it backfires?
		It could. If you're right, and ${Cat} is really hiding a soft core behind that tough exterior, then your choice might really wound ${cem}. 

		But is that such a bad thing? It might allow you to know ${cem} better. $!{ce} might finally let someone in. 

If you think about it, this is the perfect opportunity to explore the resilience of your relationships. A safe, controlled environment with clearly defined rules. 

Because this is a safe environment. Right? Nothing bad is going to happen. 
*return